【脑洞大赛】第四组-52Pi团队-爆改助动车

/*
   8*8点整屏幕和音效的驱动
   via：井底添蛙 & 骑驴玩儿漂移
   编写时间:20160723

*/

#define CLK 13                //绿色
#define MO  11                 //白色
#define CS  10                  //黑色
#define BUZZER  A0              //喇叭
#define BREAK   A3              //刹车
#define modePin       8        //模式引脚
#define micA1  3               //arduino与语音模块对应的引脚 
#define micA2  4
#define micA3  5
#define micA4  6
#define micA5  7

int modeState = 0;               //定义模式初始状态，总共3个模式，0，1，2  分别为：静音模式， 老邓模式，逗逼模式
long modeStateChangeTime = 0;    //定义模式状态变化初始值
long musicPlayTime1 = 0;         //不能改，控制信号语音及时播报相关
long musicPlayTime = 0;

const byte interruptPin = 2;   //中断检测引脚
volatile byte state = LOW;     //中断默认状态
int button_all = 1;

/* 点阵缓存变量 */
unsigned char LED_Buffer[3][8] = {
  0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,  //RED
  0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,  //GREEN
  0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,  //BLUE
};
unsigned char LED_bmp[][8] = {
  0x81, 0x42, 0x24, 0x18, 0x18, 0x24, 0x42, 0x81, //叉
  0x18, 0x3c, 0x7e, 0xff, 0x3c, 0x3c, 0x3c, 0x3c, //箭头
  0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF,  //停止红灯全亮
  0x8, 0xC, 0xFE, 0xFF, 0xFF, 0xFE, 0xC, 0x8,

};

char LED_SendByte(char data)
{
  int x;
  for (x = 0; x < 8; x++)
  {
    digitalWrite(MO, 0x80 & (~(data << x)));
    digitalWrite(CLK, LOW);
    digitalWrite(CLK, HIGH);
  }
}

void LED_Reload() //不停的刷新LED_Buffer显示
{
  int x, y;
  char z = 0x01;
  for (y = 0; y < 30; y++)
  {
    for (x = 0; x < 8; x++)
    {
      digitalWrite(CS, LOW);
      LED_SendByte(LED_Buffer[0][x]); //r
      LED_SendByte(LED_Buffer[2][x]); //g
      LED_SendByte(LED_Buffer[1][x]); //b
      LED_SendByte(~(z << x));      //seg
      digitalWrite(CS, HIGH);
      delay(1);
    }
  }
}

void LED_black() //关闭显示
{
  digitalWrite(CS, LOW);
  LED_SendByte(0x00);
  LED_SendByte(0x00);
  LED_SendByte(0x00);
  LED_SendByte(0x00);
  digitalWrite(CS, HIGH);
}

void LED_BufferClear() //清除Buffer
{
  int x, y;
  LED_black();
  for (x = 0; x < 3; x++)
  {
    for (y = 0; y < 8; y++)
    {
      LED_Buffer[x][y] = 0x00;
    }
  }
}
/*  模式0 为关闭，模式1 为老邓模式  模式2 为逗逼模式
    歌谱里面的：
    模式1
    1.启动引擎
    2.行驶音
    3.左拐了
    4.右拐了
    5.刹车
    6.让-让
    模式2
*/
void turn_left()                    //左拐： 左拐了  第三首歌
{
  digitalWrite(micA1, LOW);
  digitalWrite(micA2, LOW);
  delay(50);
  digitalWrite(micA1, HIGH);
  digitalWrite(micA2, HIGH);
}

void turn_right()
{
  digitalWrite(micA3, LOW);          //右拐： 右拐了  第四首歌
  delay(50);
  digitalWrite(micA3, HIGH);
}

void stopped()                     //刹车： 老邓哎呀妈呀  第五首歌
{
  digitalWrite(micA1, LOW);
  digitalWrite(micA3, LOW);
  delay(50);
  digitalWrite(micA1, HIGH);
  digitalWrite(micA3, HIGH);
}

void buzzer()                        //喇叭：让一让 第六首歌
{
  digitalWrite(micA2, LOW);
  digitalWrite(micA3, LOW);
  delay(50);
  digitalWrite(micA2, HIGH);
  digitalWrite(micA3, HIGH);
}

void backgroundMusic()
{
  digitalWrite(micA2, LOW);
  delay(50);
  digitalWrite(micA2, HIGH);
}

void musicMode()
{
  switch (modeState) {
    case 0:
      {
        digitalWrite(micA1, LOW);      //第七首歌，报模式 0
        digitalWrite(micA2, LOW);
        digitalWrite(micA3, LOW);
        delay(50);
        digitalWrite(micA1, HIGH);
        digitalWrite(micA2, HIGH);
        digitalWrite(micA3, HIGH);
      } break;
    case 1:
      {
        digitalWrite(micA4, LOW);      //第八首歌，报模式 1
        delay(50);
        digitalWrite(micA4, HIGH);
      } break;
    case 2:
      {
        digitalWrite(micA1, LOW);       // 第九首歌，报模式 2
        digitalWrite(micA4, LOW);
        delay(50);
        digitalWrite(micA1, HIGH);
        digitalWrite(micA4, HIGH);
      } break;
    default:
      break;
  }
}

void setup() {
  Serial.begin(9600); //串口初始化

  //pinMode(interruptPin, INPUT_PULLUP);           //定义中断引脚，并上拉
  // attachInterrupt(digitalPinToInterrupt(interruptPin), stateChange, LOW);          //初始化中断函数

  pinMode(A0, INPUT_PULLUP);  //定义控制信号引脚
  pinMode(A1, INPUT_PULLUP);
  pinMode(A2, INPUT_PULLUP);
  pinMode(A3, INPUT_PULLUP);

  pinMode(modePin, INPUT_PULLUP);         //初始化模式控制引脚

  pinMode(CLK, OUTPUT);                  //初始化点阵控制引脚
  pinMode(MO, OUTPUT);
  pinMode(CS, OUTPUT);
  digitalWrite(CS, HIGH);
  digitalWrite(CLK, HIGH);
  digitalWrite(MO, HIGH);

  LED_black();                        // 初始化8x8点阵

  for (int m = 3; m <= 7; m++)        //初始化音乐播放引脚
  {
    pinMode(m, OUTPUT);
    digitalWrite(m, HIGH);
  }

  delay(1000);                      //语音模块开机需要1秒，等待它一下
  digitalWrite(micA1, LOW);             //开机声音
  delay(50);
  digitalWrite(micA1, HIGH);
  delay(5000);
}
void loop() {

  if ((digitalRead(modePin) == 0) & ((millis() - modeStateChangeTime) >= 3000))  //判断模式
  {
    modeStateChangeTime = millis();
    modeState++;
    if (modeState > 2)modeState = 0;

    Serial.print("modeStateChange =");
    Serial.println(modeState);

    // musicMode();
  }

  if ((millis() - musicPlayTime) >= 2600 )
  {
    backgroundMusic();  //背景音乐 突突突
    musicPlayTime = millis();
    Serial.println("backgroundMusic !");
  }

  LED_BufferClear();
  for (int x = 0; x < 8; x++)
  {
    LED_Buffer[2][x] = LED_bmp[3][x];
  }
  LED_Reload();
  LED_black();
  delay(200);




  while (analogRead(A0) < 300)   //如果低电平，喇叭就响了
  {
    Serial.println("A0 !");

    if ((millis() - musicPlayTime1) >= 5000 )
    {
      musicPlayTime1 = millis();
      buzzer();
    }
  }

  while (analogRead(A1) < 300)   // 左转状态，左转灯，左拐了音效
  {
    Serial.println("A1 !");

    if ((millis() - musicPlayTime1) >= 5000 )
    {
      musicPlayTime1 = millis();
      turn_left();
    }

    LED_BufferClear();
    delay(200);
    for (int x = 0; x < 8; x++)
    {
      LED_Buffer[1][x] = LED_bmp[1][7 - x];
    }
    LED_Reload();
  }

  while (analogRead(A2) < 300)    //右转状态，左转灯， 右拐了音效
  {
    Serial.println("A2 !");

    if ((millis() - musicPlayTime1) >= 5000 )
    {
      musicPlayTime1 = millis();
      turn_right();   //右转先放音乐
    }

    LED_BufferClear();
    delay(200);
    for (int x = 0; x < 8; x++)    //然后刷点阵buffer
    {
      LED_Buffer[1][x] = LED_bmp[1][x];
    }
    LED_Reload();
  }

  while (analogRead(A3) < 300 )    //刹车
  {
    Serial.println("A3 !  ");

    if ((millis() - musicPlayTime1) >= 3000 )
    {
      musicPlayTime1 = millis();
      stopped();
    }

    LED_BufferClear();
    delay(200);
    for (int x = 0; x < 8; x++)
    {
      LED_Buffer[0][x] = LED_bmp[2][x];
    }
    LED_Reload();
  }
  musicPlayTime1 = 0;
  LED_black();
}
复制代码