改造一个 USB 亮度计

#include "USBHost_t36.h"

 

// 通讯参数要求： 9600,Data Bits: 7, Parity:Even, Stop Bits：2

#define USBHOST_SERIAL_7E2 0x1207

// 按键间隔（在间隔以内再次发生的按键都会被忽略）

#define KEYDELAY 2000

 

// 设置使用 A1 Pin 触发发送

#define PRESSKEY A1

// 发送标志 true-发送 false-不发送

boolean Pressed=false;

// 按键触发时间

unsigned long Elsp;

 

char *cmdECHOOFF = "ECHO 0"; //关闭命令回显

char *cmdSETUNIT = "UNIT:PHOTOMETRIC LX"; //设定照度返回单位

char *cmdREAD    = "MEASURE:PHOTO?";  //读取照度

char *cmdVERSION = "VERSION?";  //显示版本

 

 

USBHost myusb;

USBSerial userial(myusb);

 

void setup() {

  Serial.begin(115200);

 // while (!Serial && (millis() < 5000)) ; // wait for Arduino Serial Monitor

 

  // 设置使用 PRESSKEY 触发中断

  pinMode(PRESSKEY,INPUT_PULLUP);

  attachInterrupt(digitalPinToInterrupt(PRESSKEY), KeyAssert, RISING);

  Serial.println("Starting....");

  myusb.begin();

  userial.begin((uint32_t) 9600,(uint32_t) USBHOST_SERIAL_7E2);

  // 打开键盘

  Keyboard.begin();

  //开始后需要等待设备准备好

  delay(5000);

}

 

byte Status=0;

String revData="";

String HumanReadable="";

 

void KeyAssert() {

  Pressed=true;

}

 

// 将设备的科学计数法转为常用的表示，结果在 ToStr 中

void SciToStr(String s) {

/*分析设备返回的结果，得到有效数字和小数点位置*/

  // 有效数字

  int long validNum;

  // 小数点位置，就是 E 后面的数值

  int zeroPostion;

  String sSub;

 

  // Step1. 找到第一个空格，空格之前的就是有效数字

  sSub=s.substring(0,s.indexOf(' '));

  validNum=sSub.toInt();   

 

  // Step2. 将第一个空格之后的字符串切割到另外的字符串中

  sSub=s.substring(s.indexOf(' ')+1,s.length());

 

  //Step3. 处理指数位

  if (sSub.indexOf('-')!=-1) {

      // 有负号,切割从负号到下一个空格

      sSub=sSub.substring(sSub.indexOf('-')+1,sSub.indexOf(' '));

      zeroPostion=-sSub.toInt();

    }

  else {

      // 没有负号

      sSub=sSub.substring(sSub.indexOf('E')+1,sSub.indexOf(' '));

      zeroPostion=sSub.toInt();

  }

/*分析结束*/

 

/*根据前面结果,将字符串转为人类易读的字符串*/ 

   String tmp;

 

  // 如果小数位置为正或者为0，只需要在有效数字末尾添加 0 即可

  if (zeroPostion>=0) {

    HumanReadable=String (validNum);

    for (byte i=0;i<zeroPostion;i++) {

      HumanReadable=HumanReadable+'0';

    }

    return;

  }

 

  // 如果小数位置小于0 有两种情况：

  // 1.在左侧添加组成 0.XYZ 或者 0.0XYZ

  // 2.在数字中间加入小数点 X.YZ

  if (zeroPostion<0) {

    tmp=(String)validNum;

    // 处理情况 1

    if (abs(zeroPostion)>=tmp.length()) {

      HumanReadable="0.";

      for (byte i=0;i<abs(zeroPostion)-tmp.length();i++) {

        HumanReadable=HumanReadable+"0";

      }

      HumanReadable=HumanReadable+String(validNum);

      return;

    }

    else {

      // 处理情况 2 

      HumanReadable=tmp;

      tmp=HumanReadable.substring(0,HumanReadable.length()-abs(zeroPostion))+'.'+HumanReadable.substring(HumanReadable.length()-abs(zeroPostion));

      HumanReadable=tmp;

      return;

    }

  }     

}

 

void loop() {

    myusb.Task();

 

  char c;

 

 

  if (Status==0) {

        userial.println(cmdECHOOFF);

        Serial.println("Send EchoOff");

        delay(500);

        Serial.println("Send SETUNIT");

        userial.println(cmdSETUNIT);

        delay(500);

        Status=1;

        //if (userial.available()) {Status=1;}

  }

 

  if (Status==1) {

          userial.println(cmdREAD);

          //Serial.println("Read");

          delay(100);

          while (userial.available()) {

                c=userial.read();

                //Serial.write(c);

                // 有可能收到 0

                if (c==0) {continue;}

                revData.concat((String)c);

                if (c==0x0a) {Status=2;}

                delay(2);

          }

    }

 

  if (Status==2) {

        //Serial.print(">"); Serial.print(revData); Serial.println("<");

        SciToStr(revData);

        Serial.println(HumanReadable); 

        if ((Pressed)&(millis()>Elsp)) {

          Pressed=false;

          Keyboard.print(HumanReadable);

          Keyboard.press(KEY_DOWN);

          Keyboard.release(KEY_DOWN);

          Elsp=millis()+KEYDELAY;

        }

   

        revData="";

        Status=1;

  }

}
复制代码