【花雕学编程】Arduino动手做（225）---AS5600磁编码传感器

37款传感器与执行器的提法，在网络上广泛流传，其实Arduino能够兼容的传感器模块肯定是不止这37种的。鉴于本人手头积累了一些传感器和执行器模块，依照实践出真知（一定要动手做）的理念，以学习和交流为目的，这里准备逐一动手尝试系列实验，不管成功（程序走通）与否，都会记录下来—小小的进步或是搞不掂的问题，希望能够抛砖引玉。

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验二百二十五：AS5600磁编码器 磁感应角度测量传感器 12bit高精度模块

  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十五：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之二：将AS5600角度传感器集成到电机项目中

实验开源代码

/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十四：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之二：将AS5600角度传感器集成到电机项目中
*/

#include "AS5600.h"
#include "Wire.h"

AS5600 as5600;  //默认情况下使用Wire

//不同变量的声明

int positionZero;
const int buttonPin = 2;  //按钮的引脚号
int buttonState = 0;      //用于读取按钮状态的变量


void setup() {
  //初始化串行端口并设置串行通信的波特率
  Serial.begin(115200);

  Wire.begin();

  //使用内部上拉将按钮初始化为输入
  pinMode(buttonPin, INPUT_PULLUP);
  Serial.println("文件路径信息：");

  Serial.println(__FILE__);
  Serial.println(" ");


  //显示AS5600库的版本
  Serial.print("AS5600库的版本: ");
  Serial.println(AS5600_LIB_VERSION);


  as5600.begin(4);                         //这条线初始化AS5600传感器
  as5600.setDirection(AS5600_CLOCK_WISE);  //确定传感器的旋转方向

  //检查连接
  int b = as5600.isConnected();
  Serial.print("已连接: ");
  Serial.println(b);
  delay(5000);

  //设置零位置
  positionZero = as5600.rawAngle();
}

void loop() {
  //读取按钮状态
  buttonState = digitalRead(buttonPin);
  if (buttonState == LOW) {
    positionZero = as5600.rawAngle();
  }

  //显示相对于零点和定义方向的角度值
  Serial.print("点角值：");
  Serial.print("\t");

  //该代码行从AS5600传感器读取调整后的角度并将其显示在监视器上，
  //这可能有助于跟踪或调试。
  Serial.println(as5600.readAngle());


  //显示零的值
  Serial.print("零->位置的总值");
  //命令serial.print（“\t”）；在代码中，Arduino在串行端口上发送一个制表符（由\t表示）
  Serial.print("\t");
  Serial.println(positionZero);


  //使用AS5600传感器测量角位置
  //并以度为单位显示角度值
  conversion_de_angle();

  Serial.println("  ");
  Serial.println("  ");
  delay(3000);
}
复制代码

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十五：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之十六：转动电机轴，从AS5600读取原始数据，并计算角度、速度和位置

实验开源代码

/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十五：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之十六：转动电机轴，从AS5600读取原始数据，并计算角度、速度和位置
*/

#include <Wire.h>
#include <AS5600.h>
#include <SimpleFOC.h>

// 使用SimpleFOC库中的低通滤波器
LowPassFilter as5600_filter(0.01);
#define AS5600_ADDRESS 0x36
#define ANGLE_REG 0x0C

AS5600 encoder;

void setup() {
  Serial.begin(115200);
  Wire.begin(); // 初始化I2C
  Serial.println("完成初始化I2C，准备就绪！");
}

void loop() {
  // 读取原始位置
  uint16_t rawPosition = readAS5600Angle();
  float angle = (rawPosition * 360.0) / 4096.0; // 将原始数据转换为角度

  // 计算速度
  static float last_angle = 0;
  static unsigned long last_time = 0;
  unsigned long current_time = millis();
  float delta_time = (current_time - last_time) / 1000.0; // 转换为秒
  float speed = (angle - last_angle) / delta_time; // 角速度，单位为度/秒

  // 打印原始位置、角度和速度
  Serial.print("原始位置: ");
  Serial.print(rawPosition);
  Serial.print(" - 角度: ");
  Serial.print(angle);
  Serial.print(" 度, 速度: ");
  Serial.print(speed);
  Serial.println(" 度/秒");

  // 更新上一次的角度和时间
  last_angle = angle;
  last_time = current_time;

  delay(500); // 延迟500毫秒
}

uint16_t readAS5600Angle() {
  Wire.beginTransmission(AS5600_ADDRESS);
  Wire.write(ANGLE_REG);
  Wire.endTransmission();
  Wire.requestFrom(AS5600_ADDRESS, 2);
  uint16_t angle = Wire.read() << 8 | Wire.read();
  return angle;
}
复制代码

【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十五：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之十二：使用AS5600传感器读取角度数据，并计算步进电机的实时转速

实验开源代码

/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十五：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之十二：使用AS5600传感器读取角度数据，并计算步进电机的实时转速
*/

#include <Wire.h>
#include <SimpleFOC.h>

// 使用SimpleFOC库中的低通滤波器
LowPassFilter as5600_filter(0.01);

unsigned long lastTime = 0;
float lastAngle = 0;
float rpm = 0;

void setup() {
  Serial.begin(115200);
  Wire.begin(); // 初始化I2C
}

void loop() {
  uint16_t readValue = 0;
  byte readArray[2];

  // 通知设备即将读取数据
  Wire.beginTransmission(0x36);
  Wire.write(0x0C);
  Wire.endTransmission(false);

  // 读取数据的MSB和LSB
  Wire.requestFrom(0x36, (uint8_t)2);
  if (Wire.available() == 2) {
    readArray[0] = Wire.read();
    readArray[1] = Wire.read();
    readValue = (readArray[0] << 8) | readArray[1];
    float angle = (readValue / 4096.0) * 360.0; // 将原始数据转换为度数
    float filteredAngle = as5600_filter(angle);

    // 计算转速
    unsigned long currentTime = millis();
    float deltaTime = (currentTime - lastTime) / 1000.0; // 转换为秒
    float deltaAngle = filteredAngle - lastAngle;
    if (deltaAngle < 0) deltaAngle += 360.0; // 处理角度回绕
    rpm = (deltaAngle / 360.0) / deltaTime * 60.0; // 计算RPM

    // 更新上次的时间和角度
    lastTime = currentTime;
    lastAngle = filteredAngle;

    // 输出到串口监视器
    Serial.println(rpm);
  } else {
    Serial.println("Error reading data");
  }
  delay(20);
}
复制代码

核心芯片：AS5600
是一款易于编程的磁性旋转位置传感器，具有高分辨率 12 位模拟或 PWM 输出。这种非接触式系统测量径向磁化同轴磁体的绝对角度。这款 AS5600 专为非接触式电位计应用而设计，其坚固的设计消除了任何均匀的外部杂散磁场的影响。行业标准的I²C接口支持用户对非易失性参数进行简单编程，无需专门的编程器。此外，该器件还实现了在所谓的“3线模式”中轻松进行启动和停止位置编程，无需编程器或数字接口。输出的默认范围是 0 到 360 度。AS5600 可以通过编程零角度（开始位置）和最大角度（停止位置）来应用于较小的范围。AS5600 还配备了智能低功耗模式功能，可自动降低功耗。

AS5600框架与实物图

该芯片包含四个呈圆圈排列的霍尔传感器。 内部霍尔元件放置在封装的中心，位于半径为 1 mm 的圆圈上。

【花雕学编程】Arduino动手做（224）---AS5600磁编码传感器

典型的径向磁铁感应气隙在 0.5 mm 到 3 mm 之间，这取决于所选的磁体。更大、更强的磁铁允许更大的气隙。以 AGC 值为指导，通过调整磁体和 AS5600 之间的距离，使 AGC 值位于其范围的中心，可以找到最佳气隙。当使用直径为 0.25mm 的磁体时，参考磁体的旋转轴从封装中心的最大允许位移为 6 mm。

AS5600 允许使用 DIR 引脚控制磁铁旋转方向。如果 DIR 连接到 GND （DIR = 0），则从顶部顺时针旋转将产生计算角度的增量。如果 DIR 引脚连接到 VDD （DIR = 1），则计算的角度将逆时针旋转。

AS5600磁编码器 磁感应角度测量传感器 12bit高精度模块

非接触式磁感应角度测量模块。
精度高，多种输出方式：IIC，PWM和电压。
采用优质材料制成的高品质AS5600模块坚固耐用，不易损坏。
广泛支持，完美匹配。
电路板尺寸：23.3 × 22.8 毫米
套件重量：2.6 克
包括一个 AS5600 磁编码器模块、一个 7 针针头和一块小磁铁。

模块电原理图

电气参数：
VCC：3.3V
GND：电源地
Out：PWM /模拟电压输出
DIR：旋转方向（接地=顺时针值增加；接 VCC=顺时针值减小）
SCL：IIC 通信时钟线
SDA：IIC 数据通信线
GPO：模式选择（内部上拉接地=编程模式 B）

相关的径向磁铁也收集了不少

为做好这个系列实验，特意打印了实验架子

Arduino实验接线示意图

  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十四：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之一：从AS5600读取角度值

实验开源代码

/*
  【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
  实验二百二十四：AS5600磁编码器 磁感应角度测量传感器  12bit高精度模块
  项目实验之一：从AS5600读取角度值
*/

#include <Wire.h>
#define AS5600_I2C_ADDRESS 0x36

void setup() {
  Serial.begin(9600);
  Wire.begin();
  Serial.println("AS5600准备就绪！开始测量");
}

void loop() {
  //向AS5600请求2字节的数据
  Wire.beginTransmission(AS5600_I2C_ADDRESS);
  //角度值的注册地址
  Wire.write(0x0E);
  Wire.endTransmission();
  Wire.requestFrom(AS5600_I2C_ADDRESS, 2);

  //从AS5600读取角度值
  int angleValue = (Wire.read() << 8) | Wire.read();
  //将寄存器值转换为度数
  float angle = (float)angleValue * 0.08789;

  //打印角度到串行监视器
  Serial.print("角度：");
  Serial.print(angle);
  Serial.println("度");

  delay(2000);
}
复制代码

实验串口返回情况



这个项目实验一演示了如何通过I2C通信协议读取AS5600磁编码器的角度值。在setup()函数中，初始化了串口通信和Wire库（用于I2C通信）。在loop()函数中，通过向AS5600发送请求，并读取2个字节的数据。然后，将读取的数据转换为角度值，并打印到串口监视器中。通过调整延迟时间，可以控制采样频率。

实验场景图

conversion_de_angle函数：

void conversion_de_angle() {

  //这行代码允许通过减去参考位置来计算相对角度
  //测量的原始角度，这提供了更显著的角度测量
  //在预定义的参考位置。
  int angleBrut = as5600.rawAngle() - positionZero;  //减去零位置
  if (angleBrut < 0) angleBrut += 4096;  //管理溢出
  float angleBrutEnDegres = angleBrut * 0.088;  //转换为度
  Serial.print("读取角度值为: ");
  Serial.println(angleBrutEnDegres);
}
复制代码

实验串口返回情况

适配42步进电机，用3D打印了二种AS5600磁编码器模块的安装部件