【花雕动手做】看见声音，基于Arduino系列音乐可视器（15）

偶然心血来潮，想要做一个声音可视化的系列专题。这个专题的难度有点高，涉及面也比较广泛，相关的FFT和FHT等算法也相当复杂，不过还是打算从最简单的开始，实际动手做做试验，耐心尝试一下各种方案，逐步积累些有用的音乐频谱可视化的资料，也会争取成型一些实用好玩的音乐可视器项目。

路上捡到二根坏的LED方管灯，想改造一下废物利用。

彩灯使用WS2812B

其主要特点
智能反接保护，电源反接不会损坏IC。
IC控制电路与LED点光源公用一个电源。
控制电路与RGB芯片集成在一个5050封装的元器件中，构成一个完整的外控像素点。
内置信号整形电路，任何一个像素点收到信号后经过波形整形再输出，保证线路波形畸变不会累加。
内置上电复位和掉电复位电路。
每个像素点的三基色颜色可实现256级亮度显示，完成16777216种颜色的全真色彩显示，扫描频率不低于400Hz/s。
串行级联接口，能通过一根信号线完成数据的接收与解码。
任意两点传传输距离在不超过5米时无需增加任何电路。
当刷新速率30帧/秒时，级联数不小于1024点。
数据发送速度可达800Kbps。
光的颜色高度一致，性价比高。

主要应用领域
LED全彩发光字灯串,LED全彩模组， LED全彩软灯条硬灯条,LED护栏管。
LED点光源,LED像素屏,LED异形屏，各种电子产品，电器设备跑马灯。

WS2812B灯带选用的是每米60灯黑底裸板

声音模块，使用性价比更高的MAX4466声音传感器

MAX4466功能框图



附件：MAX4466相关技术资料链接（英文，来自MAXIM美信公司官网）
https://datasheets.maximintegrated.com/en/ds/MAX4465-MAX4469.pdf

附注：MAXIM
是美信公司（Maxim Integrated Products）的英文缩写，全球最好的模拟信号和混合信号半导体公司。Maxim Integrated Products成立于1983年，总部位于美国加利福尼亚的Sunnyvale，公司拥有9300多名员工，是世界范围内模拟和混合信号集成产品的设计、开发与生产领域的领导者之一。通过对温度、压力、声音等现实世界的各种信号进行检测、放大，并将其转换成计算机处理所需要的数字信号, Maxim的电路把现实世界与数字世界“连接”在一起。Maxim是全球模拟、混合信号、高频及数字电路设计、研发、制造的领导者，所提供的产品能够实现上述数字内核与周边系统的连接。它们在世界范围内拥有大约35,000个大型客户。
MAXIM官网：https://www.maximintegrated.com/cn.html

MAX4466模块特点
电源电压：+2.4V至+5.5V（可直接接STM/ARDUNIO/树莓派等开发板）
电源抑制比：112dB
共模抑制比：126dB
AVOL：125dB（RL = 100kΩ) 轨到轨输出
静态电源电流：24μA
增益带宽：600kHz
尺寸：20.8mm x 13.8mm x 7.5mm/0.8 x 0.5 x 0.3inch

该模块在 Vcc 和接地引线上都包含铁氧体，以最大限度地减少电源噪声。如果与 MCU 一起使用，最好使用 2.4V – 5.5V 范围内可用的最安静的电源。在 Arduino 上，这通常是 3.3V 电源。

输出是直流耦合的。当输出信号处于静止状态时，它将位于 Vcc/2。如果 Vcc 为 5V，则输出将为 2.5V。如果输出需要交流耦合，可以在输出引脚和它驱动的电路的输入之间增加一个100uF的电容。

背面的小型单圈电位器可让您将增益从 25x 调整到 125x。逆时针旋转电位器会增加增益，而逆时针旋转会降低增益。

二只灯管准备分别使arduino nano和 ESP32_C3开发板

arduino nano开发板接脚图

ESP32_C3开发板接脚图

两套横排LED方管灯所需的硬件

  【花雕动手做】有趣好玩音乐可视化（15）--横排LED方管灯
  项目之一：Arduino 和 FastLED多彩音乐节拍灯

/*
  【花雕动手做】有趣好玩音乐可视化（15）--横排LED方管灯
  项目之一：Arduino 和 FastLED多彩音乐节拍灯
*/

#include <FastLED.h>
#define SAMPLEPERIODUS 200
#define MIC_PIN A0
#define LED_DT 6
#define COLOR_ORDER GRB
#define LED_TYPE WS2812
#define NUM_LEDS 24
uint8_t max_bright = 77;
struct CRGB leds[NUM_LEDS];
CRGBPalette16 currentPalette = RainbowColors_p;
CRGBPalette16 targetPalette;

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
  LEDS.addLeds<LED_TYPE, LED_DT, COLOR_ORDER>(leds, NUM_LEDS);
  FastLED.setBrightness(max_bright);
}

float bassFilter(float sample) {
  static float xv[3] = {0, 0, 0}, yv[3] = {0, 0, 0};
  xv[0] = xv[1]; xv[1] = xv[2];
  xv[2] = sample / 9.1f;
  yv[0] = yv[1]; yv[1] = yv[2];
  yv[2] = (xv[2] - xv[0]) + (-0.7960060012f * yv[0]) + (1.7903124146f * yv[1]);
  return yv[2];
}

float envelopeFilter(float sample) {
  static float xv[2] = {0, 0}, yv[2] = {0, 0};
  xv[0] = xv[1];
  xv[1] = sample / 160.f;
  yv[0] = yv[1];
  yv[1] = (xv[0] + xv[1]) + (0.9875119299f * yv[0]);
  return yv[1];
}

float beatFilter(float sample) {
  static float xv[3] = {0, 0, 0}, yv[3] = {0, 0, 0};
  xv[0] = xv[1]; xv[1] = xv[2];
  xv[2] = sample / 7.015f;
  yv[0] = yv[1]; yv[1] = yv[2];
  yv[2] = (xv[2] - xv[0]) + (-0.7169861741f * yv[0]) + (1.4453653501f * yv[1]);
  return yv[2];
}

void loop() {
  unsigned long time = micros();
  float sample, value, envelope, beat, thresh, micLev;
  for (uint8_t i = 0; ; ++i) {
    sample = (float)analogRead(MIC_PIN);
    micLev = ((micLev * 31) + sample) / 32;
    sample -= micLev;
    value = bassFilter(sample);
    value = abs(value);
    envelope = envelopeFilter(value);
    if (i == 200) {
      beat = beatFilter(envelope);
      thresh = 0.02f * 75.;

      if (beat > thresh) {
        digitalWrite(LED_BUILTIN, LOW);

        int strt = random8(NUM_LEDS / 2);
        int ende = strt + random8(NUM_LEDS / 2);
        for (int i = strt; i < ende; i++) {
          uint8_t index = inoise8(i * 30, millis() + i * 30);
          leds[i] = ColorFromPalette(currentPalette, index, 255, LINEARBLEND);
        }
      } else {
        digitalWrite(LED_BUILTIN, HIGH);
      }
      i = 0;
    }

    EVERY_N_SECONDS(5) {
      uint8_t baseC = random8();
      targetPalette = CRGBPalette16(CHSV(baseC + random8(32), 255, random8(128, 255)),
                                    CHSV(baseC + random8(64), 255, random8(128, 255)),
                                    CHSV(baseC + random8(64), 192, random8(128, 255)),
                                    CHSV(baseC + random8(),   255, random8(128, 255)));
    }

    EVERY_N_MILLISECONDS(50) {
      uint8_t maxChanges = 24;
      nblendPaletteTowardPalette(currentPalette, targetPalette, maxChanges);
    }

    EVERY_N_MILLIS(50) {
      fadeToBlackBy(leds, NUM_LEDS, 64);
      FastLED.show();
    }

    for (unsigned long up = time + SAMPLEPERIODUS; time > 20 && time < up; time = micros()) {  }

  } // for i
} // loop()
复制代码

实验场景图  动态图

多次测试调整

对外只有5V电源接口，外露声音传感器唛头

使用充电宝，或者手机充电头供电，大于1A即可

实验场景图

项目实验的视频记录（4分43秒）

https://v.youku.com/v_show/id_XN ... hcb.playlsit.page.1

  【花雕动手做】有趣好玩音乐可视化（15）--横排LED方管灯
  项目之二：MegunoLink柱状音乐灯

/*
  【花雕动手做】有趣好玩音乐可视化（15）--横排LED方管灯
  项目之二：MegunoLink柱状音乐灯
*/

#include<FastLED.h>
#include<MegunoLink.h>
#include<Filter.h>

#define N_PIXELS  69
#define MIC_PIN   A5
#define LED_PIN   12
#define NOISE 10
#define TOP   (N_PIXELS+2)
#define LED_TYPE  WS2811
#define BRIGHTNESS  22
#define COLOR_ORDER GRB

CRGB leds[N_PIXELS];
int lvl = 0, minLvl = 0, maxLvl = 10;

ExponentialFilter<long> ADCFilter(5, 0);

void setup() {
  FastLED.addLeds<LED_TYPE, LED_PIN, COLOR_ORDER>(leds, N_PIXELS).setCorrection(TypicalLEDStrip);
  FastLED.setBrightness(BRIGHTNESS);
}

void loop() {
  int n, height;
  n = analogRead(MIC_PIN);
  n = abs(1023 - n);
  n = (n <= NOISE) ? 0 : abs(n - NOISE);
  ADCFilter.Filter(n);
  lvl = ADCFilter.Current();
  //  Serial.print(n);
  //  Serial.print(" ");
  //  Serial.println(lvl);
  height = TOP * (lvl - minLvl) / (long)(maxLvl - minLvl);
  if (height < 0L) height = 0;
  else if (height > TOP) height = TOP;
  for (uint8_t i = 0; i < N_PIXELS; i++) {
    if (i >= height) leds[i] = CRGB(0, 0, 0);
    else leds[i] = Wheel( map( i, 0, N_PIXELS - 1, 30, 150 ) );
  }
  FastLED.show();
}

CRGB Wheel(byte WheelPos) {
  if (WheelPos < 85)
    return CRGB(WheelPos * 3, 255 - WheelPos * 3, 0);
  else if (WheelPos < 170) {
    WheelPos -= 85;
    return CRGB(255 - WheelPos * 3, 0, WheelPos * 3);
  } else {
    WheelPos -= 170;
    return CRGB(0, WheelPos * 3, 255 - WheelPos * 3);
  }
}
复制代码

实验的视频记录之一（1分50秒）

https://v.youku.com/v_show/id_XN ... hcb.playlsit.page.3

实验的视频记录之二（50秒）

https://v.youku.com/v_show/id_XN ... hcb.playlsit.page.1