设为首页收藏本站
首页 > 论坛 > Arduino

[项目]【FireBeetle Board-ESP32应用教程】跑步运动的计步神器 精华

Chocho2017 | 初级技匠 | 创造力： | 帖子： | 发消息 | 串个门 | 加好友 | 打招呼
2017-6-13 15:20:38 [显示全部楼层]
41614浏览
23回复
13收藏
查看: 41614|回复: 24

[项目] 【FireBeetle Board-ESP32应用教程】跑步运动的计步神器

[复制链接]
曾几何时
我也是个运动健儿，骑单车、打羽毛球，不落下风
曾几何时
骑着我的捷安特，问道青城山，驰骋都江堰，毫不逊色
而如今
。。。 。。。 。。。
:'(:'(:'(:'(:'(:'(:'(:'(:'(:'(

    于此，为了昔日健硕的身躯，我下定决心重新出发，锻炼身体。每天坚持跑步两公里。咦？得有一个计步器记录每天的步数。于是，就有了这个计步神器的诞生，先来一发视频：


    此神器，可以实时的记录步数（以及消耗的卡路里），可以显示时间，最炫酷的当然是以指针的形式显示时间：
【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图10

还可以将数据上传到网络，通过手机软件（Blynk）显示数据，同时获取网络时间（就不用担心电池没电了时间跑飞）。

所需硬件：
     DFR0478 FireBeetle Board-ESP32
     DFR0486  OLED12864显示屏
     SEN0140 加速度计模块
      3.7V锂电池（这个是在网上买的，容量是600mAH）
      3个按键（网上买的）
手机软件用的是Blynk，搭建起来方便，关于如何使用Blynk建立IoT项目，可以参考我之前的帖子，点击链接。

1、创建一个Blynk项目
    添加如下两个控件：
      Value Display × 1
      Real-time clock × 1
    其中Real-time clock控件的属性不需要任何设置，Value Display控件名称设置成steps，INPUT引脚选择V1。然后调整两个控件的布局，如下图所示：
【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图9


2、下载程序到FireBeetle Board-ESP32
    程序源码，点击下载，源码中还包括了库文件和3D打印文件，需要将库文件放到Arduino IDE的libraries下面，3D文件可以直接打印出外壳。
    主程序代码如下：
  1. #include <TimeLib.h>

  2. #include <Wire.h>  // Only needed for Arduino 1.6.5 and earlier

  3. #include "SSD1306.h" // alias for `#include "SSD1306Wire.h"`

  4. #include "OLEDDisplayUi.h"

  5. #include "images.h"

  6. #include <SimpleTimer.h>

  7. #include <WiFi.h>

  8. #include <WiFiClient.h>

  9. #include <BlynkSimpleEsp32.h>

  10. #include <WidgetRTC.h>

  11. 

  12. #define POWER_KEY 1

  13. #define MENU_KEY  2

  14. #define UPLOAD_KEY 3

  15. 

  16. boolean upload = false;

  17. 

  18. SSD1306  display(0x3c, 18, 0);

  19. 

  20. OLEDDisplayUi ui ( &display );

  21. 

  22. SimpleTimer timer;

  23. WidgetRTC rtc;

  24. 

  25. int screenW = 128;

  26. int screenH = 64;

  27. int clockCenterX = screenW/2;

  28. int clockCenterY = ((screenH-16)/2)+16;   // top yellow part is 16 px height

  29. int clockRadius = 23;

  30. 

  31. #define DEVICE (0x53)      //ADXL345 device address

  32. #define TO_READ (6)        //num of bytes we are going to read each time (two bytes for each axis)

  33. 

  34. byte buff[TO_READ] ;        //6 bytes buffer for saving data read from the device

  35. char str[100];              //string buffer to transform data before sending it to the serial port

  36. int regAddress = 0x32;      //first axis-acceleration-data register on the ADXL345

  37. int xx, yy, zz;                //three axis acceleration data

  38. 

  39. static int currentValue = 0;

  40. static unsigned long stepsSum=0;

  41. 

  42. char auth[] = "YourAuthToken";

  43. 

  44. // Your WiFi credentials.

  45. // Set password to "" for open networks.

  46. char ssid[] = "YourNetworkName";

  47. char pass[] = "YourPassword";

  48. 

  49. const char running_Logo_bits[] PROGMEM = {

  50.   0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,0x00,

  51.   0x64,0x03,0x00,0x00,0x00,0xF8,0x01,0x00,0x00,0x00,0xF8,0x01,0x00,0x00,0x00,0xFC,

  52.   0x01,0x00,0x00,0x00,0xFC,0x05,0x00,0x00,0x00,0xFC,0x01,0x00,0x00,0x00,0xFC,0x00,

  53.   0x00,0x00,0x00,0xF8,0x01,0x00,0x00,0x00,0xF8,0x01,0x00,0x00,0x00,0xE0,0x03,0x00,

  54.   0x00,0x60,0xF1,0x07,0x00,0x00,0x20,0xF8,0x17,0x00,0x00,0xC0,0xF8,0x0F,0x00,0x00,

  55.   0xE0,0xFB,0x17,0x00,0x00,0xC0,0xFF,0x13,0x00,0x00,0x00,0xFF,0x03,0x00,0x00,0x80,

  56.   0xFE,0x03,0x00,0x00,0x00,0xF9,0x03,0x00,0x00,0x00,0xFA,0x03,0x00,0x00,0x00,0xF8,

  57.   0x03,0x00,0x00,0x00,0xF0,0x07,0x00,0x00,0x00,0xF4,0x07,0x00,0x00,0x00,0xF4,0x0F,

  58.   0x00,0x00,0x00,0xF9,0x0F,0x00,0x00,0x00,0xFC,0x1F,0x00,0x00,0x80,0xFE,0x1F,0x00,

  59.   0x00,0x00,0xFF,0x1F,0x00,0x00,0xA0,0xFF,0x5F,0x00,0x00,0xC0,0x3F,0x3F,0x00,0x00,

  60.   0xE8,0x1F,0x3F,0x00,0x00,0xE8,0xA7,0x3E,0x00,0x00,0xF0,0x03,0x7C,0x00,0x00,0xE0,

  61.   0x05,0x7C,0x00,0x00,0xE0,0x05,0xF8,0x01,0x00,0xC0,0x01,0xF0,0x03,0x00,0xC0,0x03,

  62.   0xE8,0x07,0x00,0xC0,0x03,0x88,0x6F,0x00,0x80,0x03,0x40,0x1E,0x00,0xA0,0x03,0x40,

  63.   0xFC,0x00,0x80,0x03,0x00,0xF8,0x01,0x00,0x07,0x00,0xF4,0x00,0x00,0x07,0x00,0xE8,

  64.   0x00,0x80,0x0F,0x00,0xE8,0x00,0x90,0x0F,0x00,0xE0,0x00,0xE8,0x0F,0x00,0xE8,0x00,

  65.   0xF0,0x09,0x00,0x60,0x01,0xF0,0x04,0x00,0x00,0x00,

  66. };

  67. 

  68. // utility function for digital clock display: prints leading 0

  69. String twoDigits(int digits){

  70.   if(digits < 10) {

  71.     String i = '0'+String(digits);

  72.     return i;

  73.   }

  74.   else {

  75.     return String(digits);

  76.   }

  77. }

  78. 

  79. void clockOverlay(OLEDDisplay *display, OLEDDisplayUiState* state) {

  80.   if((hour()==0) && (minute()==0) && (second()==0))

  81.     stepsSum = 0;

  82. }

  83. 

  84. void analogClockFrame(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  85.   display->drawCircle(clockCenterX + x, clockCenterY + y, 2);

  86. 

  87.   //hour ticks

  88.   for( int z=0; z < 360;z= z + 30 ){

  89.     float angle = z ;

  90.     angle = ( angle / 57.29577951 ) ; //Convert degrees to radians

  91.     int x2 = ( clockCenterX + ( sin(angle) * clockRadius ) );

  92.     int y2 = ( clockCenterY - ( cos(angle) * clockRadius ) );

  93.     int x3 = ( clockCenterX + ( sin(angle) * ( clockRadius - ( clockRadius / 8 ) ) ) );

  94.     int y3 = ( clockCenterY - ( cos(angle) * ( clockRadius - ( clockRadius / 8 ) ) ) );

  95.     display->drawLine( x2 + x , y2 + y , x3 + x , y3 + y);

  96.   }

  97. 

  98.   // display second hand

  99.   float angle = second() * 6 ;

  100.   angle = ( angle / 57.29577951 ) ; //Convert degrees to radians

  101.   int x3 = ( clockCenterX + ( sin(angle) * ( clockRadius - ( clockRadius / 5 ) ) ) );

  102.   int y3 = ( clockCenterY - ( cos(angle) * ( clockRadius - ( clockRadius / 5 ) ) ) );

  103.   display->drawLine( clockCenterX + x , clockCenterY + y , x3 + x , y3 + y);

  104.   

  105.   // display minute hand

  106.   angle = minute() * 6 ;

  107.   angle = ( angle / 57.29577951 ) ; //Convert degrees to radians

  108.   x3 = ( clockCenterX + ( sin(angle) * ( clockRadius - ( clockRadius / 4 ) ) ) );

  109.   y3 = ( clockCenterY - ( cos(angle) * ( clockRadius - ( clockRadius / 4 ) ) ) );

  110.   display->drawLine( clockCenterX + x , clockCenterY + y , x3 + x , y3 + y);

  111. 

  112.   // display hour hand

  113.   angle = hour() * 30 + int( ( minute() / 12 ) * 6 )   ;

  114.   angle = ( angle / 57.29577951 ) ; //Convert degrees to radians

  115.   x3 = ( clockCenterX + ( sin(angle) * ( clockRadius - ( clockRadius / 2 ) ) ) );

  116.   y3 = ( clockCenterY - ( cos(angle) * ( clockRadius - ( clockRadius / 2 ) ) ) );

  117.   display->drawLine( clockCenterX + x , clockCenterY + y , x3 + x , y3 + y);

  118. }

  119. 

  120. void digitalClockFrame(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  121.   String date = String(year())+"/"+twoDigits(month())+"/"+twoDigits(day());

  122.   String timenow = String(hour())+":"+twoDigits(minute())+":"+twoDigits(second());

  123.   

  124.   display->setTextAlignment(TEXT_ALIGN_CENTER);

  125.   display->setFont(ArialMT_Plain_24);

  126.   display->drawString(clockCenterX + x , 20, timenow);

  127.   display->setFont(ArialMT_Plain_16);

  128.   display->drawString(60 , 45, date);

  129. }

  130. 

  131. void writeTo(int device, byte address, byte val) {

  132.   Wire.beginTransmission(device); //start transmission to device 

  133.   Wire.write(address);        // send register address

  134.   Wire.write(val);        // send value to write

  135.   Wire.endTransmission(); //end transmission

  136. }

  137. 

  138. //reads num bytes starting from address register on device in to buff array

  139. void readFrom(int device, byte address, int num, byte buff[]) {

  140.   Wire.beginTransmission(device); //start transmission to device 

  141.   Wire.write(address);        //sends address to read from

  142.   Wire.endTransmission(); //end transmission

  143. 

  144.   Wire.beginTransmission(device); //start transmission to device

  145.   Wire.requestFrom(device, num);    // request 6 bytes from device

  146. 

  147.   int i = 0;

  148.   while(Wire.available())    //device may send less than requested (abnormal)

  149.   { 

  150.     buff= Wire.read(); // receive a byte

  151.     i++;

  152.   }

  153.   Wire.endTransmission(); //end transmission

  154. }

  155. 

  156. void runningFrame(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  157.   float calValue = stepsSum*0.4487;

  158.   

  159.   display->setTextAlignment(TEXT_ALIGN_CENTER);

  160.   display->setFont(ArialMT_Plain_24);

  161.   display->drawString(clockCenterX , clockCenterY, str);

  162. 

  163.   sprintf(str,"%.2fcal",calValue);

  164.   display->setTextAlignment(TEXT_ALIGN_CENTER);

  165.   display->setFont(ArialMT_Plain_10);

  166.   display->drawString(100 , 20, str);

  167.   

  168.   display->drawXbm(10, 14, 34, 50, running_Logo_bits);

  169. }

  170. 

  171. void uploadFrame(OLEDDisplay *display, OLEDDisplayUiState* state, int16_t x, int16_t y) {

  172.   display->setFont(ArialMT_Plain_16);

  173.   display->drawString(60 , 45, "upload data ...");

  174. }

  175. 

  176. // This array keeps function pointers to all frames

  177. // frames are the single views that slide in

  178. FrameCallback frames[] = { analogClockFrame, digitalClockFrame, runningFrame, uploadFrame};

  179. 

  180. // how many frames are there?

  181. int frameCount = 4;

  182. 

  183. // Overlays are statically drawn on top of a frame eg. a clock

  184. OverlayCallback overlays[] = { clockOverlay };

  185. int overlaysCount = 1;

  186. 

  187. void uploadToBlynk(void){

  188.   if(upload == true){

  189.     Blynk.virtualWrite(V0,stepsSum);

  190.     Blynk.virtualWrite(V1,stepsSum);

  191.   }

  192. }

  193. 

  194. void uiInit(void){

  195.   ui.setTargetFPS(30);

  196.   //ui.setActiveSymbol(activeSymbol);

  197.   //ui.setInactiveSymbol(inactiveSymbol);

  198.   ui.setIndicatorPosition(TOP);

  199.   ui.setIndicatorDirection(LEFT_RIGHT);

  200.   ui.setFrameAnimation(SLIDE_LEFT);

  201.   ui.setFrames(frames, frameCount);

  202.   ui.setOverlays(overlays, overlaysCount);

  203.   ui.disableAutoTransition();

  204.   ui.switchToFrame(2);

  205.   ui.init();

  206.   display.flipScreenVertically();

  207. }

  208. 

  209. void adxl345Init(void){

  210.   writeTo(DEVICE, 0x2D, 0);      

  211.   writeTo(DEVICE, 0x2D, 16);

  212.   writeTo(DEVICE, 0x2D, 8);

  213. }

  214. 

  215. void updateAdxl345(void){

  216.   readFrom(DEVICE, regAddress, TO_READ, buff); //read the acceleration data from the ADXL345

  217.   xx = (((int)buff[1]) << 8) | buff[0];   

  218.   yy = (((int)buff[3])<< 8) | buff[2];

  219.   zz = (((int)buff[5]) << 8) | buff[4];

  220.   

  221.   if(xx < 100){

  222.     sprintf(str, "%d", stepsSum);  

  223.     return;

  224.   }

  225. 

  226.   if(fabs(xx - currentValue) > 80){

  227.     if(xx < currentValue){

  228.       stepsSum++;

  229.     }

  230.     currentValue = xx;

  231.   }

  232.   sprintf(str, "%d", stepsSum);  

  233. }

  234. 

  235. int getKeys(void){

  236.     if(digitalRead(D2) == LOW){

  237.       delay(5);

  238.       if(digitalRead(D2) == LOW){

  239.         while(digitalRead(D2) == LOW);

  240.         return POWER_KEY;

  241.       }

  242.     }

  243.      if(digitalRead(D3) == LOW){

  244.       delay(5);

  245.       if(digitalRead(D3) == LOW){

  246.         while(digitalRead(D3) == LOW);

  247.         return MENU_KEY;

  248.       }

  249.     }

  250.      if(digitalRead(D4) == LOW){

  251.       delay(5);

  252.       if(digitalRead(D4) == LOW){

  253.         while(digitalRead(D4) == LOW);

  254.         return UPLOAD_KEY;

  255.       }

  256.     }

  257.     return 0;

  258. }

  259. 

  260. void doKeysFunction(void){

  261.   static int uiFrameIndex = 2;

  262.   int keys = getKeys();

  263.   if(keys == POWER_KEY){

  264.     static char i = 0;

  265.     if(i){

  266.       ui.init();

  267.      display.flipScreenVertically();

  268.      display.displayOn();

  269.     }else{

  270.      display.displayOff();

  271.     }

  272.     i = ~i;

  273.   }

  274.   if(keys == MENU_KEY){

  275.     if(upload == false){

  276.       uiFrameIndex++;

  277.       if(uiFrameIndex == 3)

  278.        uiFrameIndex = 0;     

  279.       ui.switchToFrame(uiFrameIndex);

  280.     }else{

  281.       ui.switchToFrame(3);

  282.     }

  283.   }

  284.   if(keys == UPLOAD_KEY){

  285.     if(upload == true){

  286.       upload = false;

  287.       ui.switchToFrame(uiFrameIndex);

  288.     }else{

  289.       upload = true;

  290.       ui.switchToFrame(3);

  291.     }

  292.   }

  293. }

  294. 

  295. void setup() {

  296.   pinMode(D2,INPUT);

  297.   pinMode(D3,INPUT);

  298.   pinMode(D4,INPUT);

  299.   Blynk.begin(auth, ssid, pass);

  300.   rtc.begin();

  301.   uiInit();

  302.   adxl345Init();

  303. 

  304.   timer.setInterval(30,updateAdxl345);

  305.   timer.setInterval(100,uploadToBlynk);

  306. }

  307. 

  308. void loop() {

  309.   int remainingTimeBudget = ui.update();

  310.   static int testSum = 0;

  311.   if((testSum < 100) || (upload == true)){

  312.    Blynk.run();

  313.    testSum++;

  314.   }

  315.   if (remainingTimeBudget > 0) {

  316.     delay(remainingTimeBudget);

  317.   }

  318.   doKeysFunction();

  319.   timer.run();

  320. }
复制代码


    需要注意的是，将源码中的WiFi、密码，以及AUTHTOKENS改成你自己的，修改部分如下：

  1. char auth[] = "YourAuthToken";

  2. 

  3. // Your WiFi credentials.

  4. // Set password to "" for open networks.

  5. char ssid[] = "YourNetworkName";

  6. char pass[] = "YourPassword";
复制代码


3、硬件组装
    OLED12864显示屏和加速度计模块都连接到I2C，按键分别连接到D2、D3、D4，其中，按键需要加51K上拉电阻，上拉到3.3V，如下图所示：

【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图3

注意：图中上拉接到AREF是错的，需要连接到3.3V

    硬件焊接图，如下所示：

【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图1【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图2


    硬件焊接完成后，将硬件模块组装到外壳中，如下所示：

【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图4【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图5【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图6


    整体效果展示：

【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图7【FireBeetle Board-ESP32应用教程】跑步运动的计步神器图8

查看更多ESP32/ESP8266教程和项目，请点击 ： ESP32教程 汇总贴
回复

使用道具 举报

luna  初级技神

发表于 2018-12-19 14:29:26

中文版 ： ESP32教程汇总贴
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2017-6-14 13:22:09

源代码 发表于 2017-6-14 10:46
喜欢~界面非常酷！我之前也想用Blynk这款蓝牙APP，但注册几次都失败了。。。 ...

你可以能下载的版本不对，我在另外一篇帖子里面提到过的。你可以去看一下。我之前的Blynk软件就是这个问题，一直注册不成功。
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2018-6-4 10:53:27

linzzzzh 发表于 2018-5-29 17:00
请问下，timelib的库文件为什么会出现找不到的情况啊，已经在GitHub上下载过，也放到library里了 ...

是不是你的库文件与其他的库文件冲突了？
回复

使用道具 举报

源代码  中级技匠

发表于 2017-6-14 14:13:45

Chocho2017 发表于 2017-6-14 13:22
你可以能下载的版本不对，我在另外一篇帖子里面提到过的。你可以去看一下。我之前的Blynk软件就是这个问 ...

好的  我去看看
回复

使用道具 举报

精彩评论(23)

Chocho2017  初级技匠
 楼主|

发表于 2017-6-13 15:21:57

照例，自己先抢个沙发。;P;P;P;P;P;P;P;P;P
回复

使用道具 举报

秦皇岛岛主  初级技师

发表于 2017-6-13 15:35:52

楼主焊工牛B 看起来蛮帅的
回复

使用道具 举报

bobo  NPC

发表于 2017-6-13 16:41:18

UI界面不错，顶。
回复

使用道具 举报

Youyou  初级技匠

发表于 2017-6-13 19:02:34

楼主的飞线功底果然扎实，牛逼！
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2017-6-14 08:56:10

Youyou 发表于 2017-6-13 19:02
楼主的飞线功底果然扎实，牛逼！

哈哈，还行吧。谢谢夸奖。
回复

使用道具 举报

源代码  中级技匠

发表于 2017-6-14 10:46:08

喜欢~界面非常酷！我之前也想用Blynk这款蓝牙APP，但注册几次都失败了。。。
回复

使用道具 举报

hnyzcj  版主

发表于 2017-6-14 11:06:55

这个厉害了，哈哈哈
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2017-6-14 13:22:31

hnyzcj 发表于 2017-6-14 11:06
这个厉害了，哈哈哈

呵呵 ，谢谢。
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2017-6-14 15:10:25

源代码 发表于 2017-6-14 14:13
好的  我去看看

:victory::victory::victory::victory::victory::victory::victory::victory::victory::victory::victory:
回复

使用道具 举报

xiaohe9527  高级技师

发表于 2017-6-26 15:35:08

太牛逼了
回复

使用道具 举报

xiaohe9527  高级技师

发表于 2017-6-26 16:00:16

那个10自由度惯性导航模块和OLED的接线没讲清楚啊，大哥请讲一下
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2017-6-27 10:47:53

xiaohe9527 发表于 2017-6-26 16:00
那个10自由度惯性导航模块和OLED的接线没讲清楚啊，大哥请讲一下

是接I2C的，SDA接SDA，SCL接SCL。简单啦。
回复

使用道具 举报

miletian  中级技师

发表于 2017-7-6 15:26:37

虽然硬件不限听那个，打算做下试试
回复

使用道具 举报

gray6666  初级技神

发表于 2017-7-7 10:50:34

请问您的51K上拉电阻是如何测量的？
回复

使用道具 举报

Chocho2017  初级技匠
 楼主|

发表于 2017-7-7 14:55:08

gray6666 发表于 2017-7-7 10:50
请问您的51K上拉电阻是如何测量的？

51K只是个电阻的参考范围，你可以用47K的。
回复

使用道具 举报

linzzzzh  学徒

发表于 2018-5-29 17:00:20

请问下，timelib的库文件为什么会出现找不到的情况啊，已经在GitHub上下载过，也放到library里了
回复

使用道具 举报

12下一页
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

为本项目制作心愿单
购买心愿单
心愿单 编辑
[[wsData.name]]

硬件清单

  • [[d.name]]
btnicon
我也要做!
点击进入购买页面
撰写新帖
关于楼主
勋章墙
编辑选择奖 编辑选择奖

楼主的其它帖子

background 创造力兑换 background 心愿单 background 创客导航
上海智位机器人股份有限公司 沪ICP备09038501号-4

© 2013-2024 Comsenz Inc. Powered by Discuz! X3.4 Licensed

mail