查看: 7489|回复: 6

DIY语音相册 -使用Firebeetle M0主板来制作一款语音相册

[复制链接]

DIY语音相册

-使用Firebeetle M0主板来制作一款语音相册

最近一直在琢磨做一个特别的礼物。看到朋友购买实体相册送人，我想是否能够在实体相册上做一些创新呢，例如增加一些互动？

我翻看着相册里面的相片，相片往往让我回想起过往岁月的点点滴滴，往往令人感动的不是变化的事物，而是那些被相片定格的不变的瞬间。

每一个瞬间都有一段故事，为什么我们不让照片自己来讲述这段故事呢？

于是制作语音相册的想法一直在我脑海中回荡。自从看到了DFRobot推出的Firebeetle M0主板，我突然发现这个主板恰恰好能够实现我的想法。

我先来说说为什么恰恰好。Firebeetle M0主板的主芯片使用了一款ATSAMD21G18 ARM Cortex M0+ 高性能32位处理器，而且还带一路数模转换DAC，这意味着我可以通过MCU软件解析音频文件，并播放出声音。

在主板上还集成了16MB SPI Flash，可以虚拟出一个12MB的U盘用于存储数据。也就是我可以通过USB将音频文件直接存储到Flash中。我算了一下存储单声道WAV文件大概可以存储5分钟，够讲几段故事了。

在加上必要的GPIO作为按钮的输入，一个Firebeetle M0主板可以完成我的这个作品。

以下是Firebeetle M0主板的详细介绍

点击查看 Firebeetle M0主板WiKi

我购买了一本漂亮的16寸自粘式覆膜相册，封面是印象派画家柴尔德·哈萨姆的海边。

选用的部件

部件清单：

1. FIT0625 带开关两节7号电池盒（安装一对7号电池） 1只

2. FIT0192 直径36mm 8欧1W喇叭 1只

3. DFR0119-O 3W mini音频功放板1只

4. DFR0039 贴片按钮 5只

5. DFR0652 Firebeetle M0主板 1只

6. FIT0752 0.4mm耐高温焊接线（白色）1卷

7. 16寸自粘式覆膜相册 1本

准备的工具：

1. FIT0456 十字/一字两用螺丝刀1把

2. KIT0077 基础焊接工具套装（里面包含了焊接所需的烙铁、钳子、镊子等） 1套

3. FIT0641 USB Type- C线 1条

4. 双面胶 1卷

5. 电脑 1台

所用到的软件：

1． Arduino IDE 编程环境

2． Audacity音频转换软件

3． voice_album.ino 代码

制作步骤：

一、安装Arduino IDE和Firebeetle M0主板SDK，并测试开发环境

使用Firebeetle M0主板之前，首先需要下载并安装Arduino IDE开发环境，测试Firebeetle M0主板。

在Arduino官方下载最新版本的IDE开发环境。

Arduino IDE 使用入门看这里

IDE安装好以后，打开IDE，然后下载安装Firebeetle M0主板的SDK

点击File -> Preferences

1.在Preferences界面点击Additional Boards Manager URLs最左边的窗口图标，将弹出输入URL的窗口。

2.将下面的链接地址复制到新弹出的对话框中

http://download.dfrobot.top/firebeetle/package_firebeetle_index.json

3.点击OK将保存Firebeetle M0主板SDK的URL地址

4.点击Preferences界面的OK按钮保存配置

点击Tools -> Board -> Boards Manager

此时可以看到Firebeetle SAMD Board这个SDK，点击Install安装SDK

安装好以后我们就可以在Board界面看到Firebeetle M0主板的选项，我们选择Firebeetle M0

通过USB线将Firebeetle M0主板连接到电脑，此时可看到操作系统发现了一个新的COM口，我们在Port菜单选择新的这个COM口。

为了验证主板是否可以工作，我们先来运行一个简单的板上13脚LED闪烁的例子程序。

点击左上角的箭头按钮，LED闪烁程序将会编译后烧写到主板。烧写过程中主板上的13脚LED灯快速闪烁，当IDE左下角显示Done uploading说明程序下载完成。

可以看到主板上13脚的绿色LED灯按照亮一秒灭一秒的节奏闪烁，说明主板是好的，开发环境我们也搭好了。

二、使用电烙铁焊接硬件

将音频功放、喇叭和5个按钮焊接在一起，按钮的连线15厘米左右

连线示意图

三、挑选照片，讲述照片背后的故事，准备音频文件

我们挑选出照片，准备好我们想讲的故事。用手机录制5个故事的音频文件，需要注意的是声音需要大声一些，这样可以提高信噪比。

如果检查没有问题，我们将这些文件传输到PC上，它们一般是.m4a文件，我们对文件进行重命名。因为5个按键在程序里面的编号是从按键0到按键4，所以我们文件的命名也是从0到4。

这些文件是压缩后的双声道，我们需要转换为Firebeetle M0主板能够软件音频解码的WAV单声道文件。

我们使用Audacity这个开源免费的音频软件将m4a文件转换为单声道WAV文件。

下载地址：https://www.audacityteam.org/

Audacity软件安装完成后，我们还需要去下载一个免费的ffmpeg-win-2.2.2.exe插件

https://lame.buanzo.org/#lamewindl

ffmpeg-win-2.2.2.exe安装好后，在Audacity软件点击菜单Edit ->Preferences

点击Libraries ->FFmpegLibrary -> Location

选择FFmpeg安装的路径点击 OK

点击Audacity软件File -> Open打开刚才录音的0.m4a文件

点击音轨上方的下拉按钮，选择 Split Stereoto Mono 分离出单声道

点击一个声道的Mute按钮对这个声道进行静音，Project Rate选择44100Hz

点击File -> Export ->Export as WAV，导出WAV文件

Encoding选择Unsigned 8-bit PCM格式，保存0.wav文件

按照以上方法将其他4个.m4a文件转换为.wav文件

将Firebeetle M0主板通过USB线连接到电脑，双击侧面的RST按钮，此时主板上的RGB灯变成绿色，电脑也将弹出一个U盘，将准备好的5个.wav文件拷贝到这个U盘。拷贝的速度比通常的U盘慢，需要耐心等待。

拷贝完成后，我们单击RST按钮，进入到编程模式。

四、下载语音相册的代码到Firebeetle M0主板

此时打开Arduino IDE，点击Sketch -> Include Library -> Add .ZIP Librar选择附件代码文件中的AudioZero.zip音频库，此时成功加入了音频库

点击Arduino IDE 的File -> Open

打开voice_album.ino，点击Ipload按钮将语音相册的程序下载到Firebeetle M0主板

参考代码：

// voice album project
//
#include <UD.h>
#include <SPI.h>
//Here is an example of audioZero https://www.arduino.cc/en/Tutorial/SimpleAudioPlayerZero
#include <AudioZero.h>

// D12口低电平将关闭PAM8403音频功放
// When D12 is low level will turn off pam8403 audio amplifier
const byte nShoutdown = 12;

// D32 pin for SPI Flash CS pin
const byte flashCS = 32;

// 5个按钮的编号对应到Firebeetle M0 Pin
// The numbers of the five button correspond to firebeetle M0 pin
// Button  number      :| 0 | 1 | 2 | 3 | 4 |
// Firebeetle M0    Pin:| D0| D1| D3| D5| D6|

// 记录按钮按下的时刻
// Record the time when the button is pressed
volatile unsigned long triggertime = 0; 
// 去抖期的时长 （毫秒）
// Duration of dithering (mS)
volatile unsigned long delta = 500;   
volatile boolean buttonStatus[5] = {0};
volatile byte soundNumber = 0;
volatile boolean startPlay = 0;
String title = String(".wav");

// 播放控制
// Playback control
void controlPlay(void) {
  volatile byte i = 0;

  // 如果有按钮按下将停止音频播放
  // If a button is pressed, the audio will stop playing
  AudioZero.stop();
  Serial.println("stop ");
  // 如果没有播放过这个音频，此时就播放按钮对应的这个音频
  // If the audio has not been played, the audio corresponding to the button will be played at this time
  if (0 == buttonStatus[soundNumber]) {
    title = String(".wav");
    title =  soundNumber + title;
    startPlay = 1;
    for (i = 0; i < 5; i++) {
      buttonStatus[i] = 0;
    }
    buttonStatus[soundNumber] = 1;
  }
  else {
    buttonStatus[soundNumber] = 0;
  }

}

// 读取5个按钮的值，按钮的编号对应到Firebeetle M0 Pin如下
// Read the values of the five buttons. The button numbers correspond to firebeetle M0 pin as follows
// Button  number      :| 0 | 1 | 2 | 3 | 4 |
// Firebeetle M0    Pin:| D0| D1| D3| D5| D6|
void readButton(void) {

  // 如果第二次按钮中断间隔时间大于消除抖动时间，说明是一次正常的按键动作
  // If the interval between the second button interruption is greater than the time to eliminate jitter, it is a normal key action
  if (millis() - triggertime > delta) {
    triggertime = millis();
    // 读取D0引脚的电平，如果是按钮0按下调用控制播放功能
    // Read the level of D0 pin, if it is the button 0, press it to call the control playback function
    if (digitalRead(0) == 0) {
      soundNumber = 0;
      controlPlay();
      return;
    }

    // 读取D1引脚的电平，如果是按钮1按下调用控制播放功能
    // Read the level of D1 pin, if it is the button 1, press it to call the control playback function
    if (digitalRead(1) == 0) {
      soundNumber = 1;
      controlPlay();
      return;
    }

    // 读取D3引脚的电平，如果是按钮2按下调用控制播放功能
    // Read the level of D3 pin, if it is the button 2, press it to call the control playback function
    if (digitalRead(3) == 0) {
      soundNumber = 2;
      controlPlay();
      return;
    }

    // 读取D5引脚的电平，如果是按钮3按下调用控制播放功能
    // Read the level of D5 pin, if it is the button 3, press it to call the control playback function
    if (digitalRead(5) == 0) {
      soundNumber = 3;
      controlPlay();
      return;
    }

    // 读取D6引脚的电平，如果是按钮4按下调用控制播放功能
    // Read the level of D6 pin, if it is the button 4, press it to call the control playback function
    if (digitalRead(6) == 0) {
      soundNumber = 4;
      controlPlay();
      return;
    }
  }
}

// 初始化设置函数，程序从这里开始
// Initialization setting function, the program starts from here
void setup()
{
  // 设置音频功放关闭控制脚为输出
  // Set the audio amplifier off control pin as output
  pinMode(nShoutdown, OUTPUT);
  // 关闭音频功放
  // Audio power amplifier off
  digitalWrite(nShoutdown, LOW);

  // 设置5个按钮接口为输入，并且上拉使能，按钮的编号对应到Firebeetle M0 Pin如下
  // The numbers of the five button correspond to firebeetle M0 pin
  // Button  number      :| 0 | 1 | 2 | 3 | 4 |
  // Firebeetle M0    Pin:| D0| D1| D3| D5| D6|
  // 设置| D0| D1| D3| D5| D6|为输入中断
  // Set | D0 | D1 | D3 | D5 | D6 | as input interrupt
  pinMode(0, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(0), readButton, FALLING );
  pinMode(1, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(1), readButton, FALLING );
  pinMode(3, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(3), readButton, FALLING );
  pinMode(5, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(5), readButton, FALLING );
  pinMode(6, INPUT_PULLUP);
  attachInterrupt(digitalPinToInterrupt(6), readButton, FALLING );

  Serial.begin(115200);
  Serial.print("Initializing SD card...");
  //D32 pin for SPI Flash CS pin
  if (!UD.begin(flashCS)) {
    Serial.println(" failed!");
    while (true);
  }
  Serial.println(" done.");
  // 44100kHz mono sample rate
  AudioZero.begin(44100);
}

// 程序主循环
// Program main loop
void loop ()
{
  byte flag = 0;
  // 如果startPlay标志置位，控制播放
  // If the startplay flag is set, the playback is controlled
  if (1 == startPlay) {
    startPlay = 0;
    // 按照音频文件名读取文件
    // Read audio file name according to
    UDFile myFile = UD.open(title);
    if (!myFile) {
      // if the file didn't open, print an error and stop
      Serial.println("error opening .wav file");
    }
    else {
      // 开启音频功放
      // Turn on audio amplifier
      digitalWrite(nShoutdown, HIGH);
      Serial.print("Playing ");
      Serial.println(soundNumber);
      // 返回byte: false:音频播放完毕; true:音频播放过程中中断停止
      // Return byte: false: audio playback finished; true: interrupt stop during audio playback
      // until the file is not finished
      flag = AudioZero.play(myFile);
      if (false == flag) {
        buttonStatus[soundNumber] = 0;
      }
      Serial.println("End of file. Thank you for listening!");

      // 播放完毕关闭音频功放
      // Turn off the audio amplifier after playing
      digitalWrite(nShoutdown, LOW);
    }
  }
}
复制代码