ESP32_C3 连接 MPU6050 获取运动数据

前段时间，买了一块SEN0142模块，核心就是MPU6050，也就是一个六轴加速度传感器：


这块板子，只有英文资料：6_DOF_Sensor-MPU6050__SKU_SEN0142_-DF机器人 (dfrobot.com)
DFRobot的中文WiKi上，没有看到相关的资料，商城也没有看到有卖的。

上面的英文资料中，给出的实例是Arduino UNO的：


我将SEN0142连接到当前使用的ESP32_C3：


使用上面的例程，发现并不好使。

后来专门找到了Adafruit相关的实例，成功实现了通过I2C获取SEN0142模块的数据。

MPU6050是一种非常流行的空间运动传感器芯片，可以当前的三个加速度分量和三个旋转角速度，在航模、手持设备中，都使用广泛。

通过MPU6050，我们可以传感器当前在XYZ三个轴上的加速度，以及绕XYZ三个轴的角速度，从而感知传感器在空间运动的状态。
通常该传感器通过I2C设备与开发板相连，获取的数据包含如下的信息：

• 0x3B，加速度计的X轴分量ACC_X
• 0x3D，加速度计的Y轴分量ACC_Y
• 0x3F，加速度计的Z轴分量ACC_Z
• 0x41，当前温度TEMP
• 0x43，绕X轴旋转的角速度GYR_X
• 0x45，绕Y轴旋转的角速度GYR_Y
• 0x47，绕Z轴旋转的角速度GYR_Z
• 
  

先将该传感器，按照下图，与ESP32_C3连接起来：

然后，实际操作读取数据去前，使用了一个小程序，来检测I2C设备：

#include <Wire.h>
 
void setup() {
  Wire.begin();
 
  Serial.begin(115200);
  while (!Serial);
  Serial.println("\nI2C Scanner");
}

void loop() {
  int nDevices = 0;
 
  Serial.println("Scanning...");
 
  for (byte address = 1; address < 127; ++address) {
    Wire.beginTransmission(address);
    byte error = Wire.endTransmission();
 
    if (error == 0) {
      Serial.print("I2C device found at address 0x");
      if (address < 16) {
        Serial.print("0");
      }
      Serial.print(address, HEX);
      Serial.println("  !");
 
      ++nDevices;
    } else if (error == 4) {
      Serial.print("Unknown error at address 0x");
      if (address < 16) {
        Serial.print("0");
      }
      Serial.println(address, HEX);
    }
  }
  if (nDevices == 0) {
    Serial.println("No I2C devices found\n");
  } else {
    Serial.println("done\n");
  }
  delay(5000); // Wait 5 seconds for next scan
}
复制代码

下载该程序后，打开串口监听，会有如下的返回信息：


其中会列出当前连接的I2C设备的地址，MPU6050默认为0x68。
如果没有找到I2C设备，说明连接没有连好。

在使用完整的读取MPU6050数据的代码：

// Basic demo for accelerometer readings from Adafruit MPU6050

// ESP32 Guide: https://RandomNerdTutorials.com/esp32-mpu-6050-accelerometer-gyroscope-arduino/
// ESP8266 Guide: https://RandomNerdTutorials.com/esp8266-nodemcu-mpu-6050-accelerometer-gyroscope-arduino/
// Arduino Guide: https://RandomNerdTutorials.com/arduino-mpu-6050-accelerometer-gyroscope/

#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>

Adafruit_MPU6050 mpu;

void setup(void) {
  Serial.begin(115200);
  while (!Serial)
    delay(10); // will pause Zero, Leonardo, etc until serial console opens

  Serial.println("Adafruit MPU6050 test!");

  // Try to initialize!
  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1) {
      delay(10);
    }
  }
  Serial.println("MPU6050 Found!");

  mpu.setAccelerometerRange(MPU6050_RANGE_8_G);
  Serial.print("Accelerometer range set to: ");
  switch (mpu.getAccelerometerRange()) {
  case MPU6050_RANGE_2_G:
    Serial.println("+-2G");
    break;
  case MPU6050_RANGE_4_G:
    Serial.println("+-4G");
    break;
  case MPU6050_RANGE_8_G:
    Serial.println("+-8G");
    break;
  case MPU6050_RANGE_16_G:
    Serial.println("+-16G");
    break;
  }
  mpu.setGyroRange(MPU6050_RANGE_500_DEG);
  Serial.print("Gyro range set to: ");
  switch (mpu.getGyroRange()) {
  case MPU6050_RANGE_250_DEG:
    Serial.println("+- 250 deg/s");
    break;
  case MPU6050_RANGE_500_DEG:
    Serial.println("+- 500 deg/s");
    break;
  case MPU6050_RANGE_1000_DEG:
    Serial.println("+- 1000 deg/s");
    break;
  case MPU6050_RANGE_2000_DEG:
    Serial.println("+- 2000 deg/s");
    break;
  }

  mpu.setFilterBandwidth(MPU6050_BAND_5_HZ);
  Serial.print("Filter bandwidth set to: ");
  switch (mpu.getFilterBandwidth()) {
  case MPU6050_BAND_260_HZ:
    Serial.println("260 Hz");
    break;
  case MPU6050_BAND_184_HZ:
    Serial.println("184 Hz");
    break;
  case MPU6050_BAND_94_HZ:
    Serial.println("94 Hz");
    break;
  case MPU6050_BAND_44_HZ:
    Serial.println("44 Hz");
    break;
  case MPU6050_BAND_21_HZ:
    Serial.println("21 Hz");
    break;
  case MPU6050_BAND_10_HZ:
    Serial.println("10 Hz");
    break;
  case MPU6050_BAND_5_HZ:
    Serial.println("5 Hz");
    break;
  }

  Serial.println("");
  delay(100);
}

void loop() {
  /* Get new sensor events with the readings */
  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);

  /* Print out the values */
  Serial.print("Acceleration X: ");
  Serial.print(a.acceleration.x);
  Serial.print(", Y: ");
  Serial.print(a.acceleration.y);
  Serial.print(", Z: ");
  Serial.print(a.acceleration.z);
  Serial.println(" m/s^2");

  Serial.print("Rotation X: ");
  Serial.print(g.gyro.x);
  Serial.print(", Y: ");
  Serial.print(g.gyro.y);
  Serial.print(", Z: ");
  Serial.print(g.gyro.z);
  Serial.println(" rad/s");

  Serial.print("Temperature: ");
  Serial.print(temp.temperature);
  Serial.println(" degC");

  Serial.println("");
  delay(500);
}
复制代码

编译前，需要先安装调用的库：

点按安装时，会提示安装关联的库，选择一并安装即可。

安装完成，即可编译下载后，打开串口监听工具，移动传感器，可以看到如下的信息：


如果对着传感器哈气，对应的Temperature值会上升，表示当前温度。
其他的数据：
加速度：Acceleration X: 3.45, Y: 9.25, Z: -0.96 m/s^2
角速度：Rotation X: -0.01, Y: 0.02, Z: -0.00 rad/s


通过以上的数据，再结合一定的算法，就能够用于非空等场合了。

不错子