【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
DHT11模块是一种常用的数字温湿度传感器，能够测量环境的温度和相对湿度，并将这些数据以数字信号的形式输出。1、主要特点
高可靠性和长期稳定性: DHT11模块内置了一个电阻式感湿元件和一个NTC测温元件，并与一个高性能8位单片机相连接，确保了数据的准确性和稳定性。
数字信号输出: 采用单总线协议，数据传输速率较慢，但能够保证数据传输的准确性和稳定性。
低成本和易用性: 结构简单，价格便宜，适用于各种温湿度监测系统。
2、技术参数
温度测量范围: 0~50°C，误差±2°C。
湿度测量范围: 20%~90%RH，误差±5%RH。
供电电压: 3~5.5V。
接口类型: 单总线接口，数据传输距离可达20米以上。
3、引脚说明
VCC: 供电引脚，连接3~5.5V电源。
GND: 接地引脚，连接电源负极。
DATA: 数据引脚，用于与主机通信。
NC: 空脚，无需连接。
4、工作原理
感应温湿度: DHT11内部包含一个电阻式感湿元件和一个NTC测温元件，这些元件感应周围环境的温度和湿度。
信号转换: 感应到的温湿度信号被转换成数字信号。
数据传输: 主机（如Arduino）通过发送一个复位信号来启动DHT11模块。模块响应并传输40位数据，这些数据包括：
湿度整数部分: 8位
湿度小数部分: 8位
温度整数部分: 8位
温度小数部分: 8位
校验和: 8位，用于验证数据的完整性
5、数据传输过程
启动信号: 主机发送一个低电平信号，持续至少18毫秒，然后拉高电平，等待20-40微秒。
响应信号: DHT11模块检测到启动信号后，发送一个80微秒的低电平响应信号，然后发送一个80微秒的高电平信号，表示准备好发送数据。
数据传输: 模块开始传输40位数据，每位数据由一个50微秒的低电平信号和一个高电平信号组成。高电平信号的持续时间决定了数据位的值（26-28微秒表示0，70微秒表示1）。
校验和: 主机接收完40位数据后，计算前32位数据的校验和，并与接收到的校验和进行比较。如果两者一致，数据有效；否则，数据无效。
【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）实验二百三十二：ESP32-S3 WROOM N16R8 CAM开发板WiFi+蓝牙模块
OV2640/5640摄像头模组
{花雕动手做}项目之二十九：ESP32-S3 CAM使用DHT11模块测量温湿度
实验开源代码
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验二百三十二：ESP32-S3 WROOM N16R8 CAM开发板WiFi+蓝牙模块
OV2640/5640摄像头模组
{花雕动手做}项目之二十九：ESP32-S3 CAM使用DHT11模块测量温湿度
*/
#include "DHTesp.h" // 点击这里获取库: http://librarymanager/All#DHTesp
#include <Ticker.h> // 引入Ticker库，用于定时任务
#ifndef ESP32
#pragma message(THIS EXAMPLE IS FOR ESP32 ONLY!)
#error Select ESP32 board.
#endif
/**************************************************************/
/* 示例如何使用多任务从ESP32读取DHT传感器。 */
/* 该示例依赖于Ticker库每20秒唤醒一次任务。 */
/**************************************************************/
DHTesp dht; // 创建DHTesp对象
void tempTask(void *pvParameters); // 声明温度任务函数
bool getTemperature(); // 声明获取温度函数
void triggerGetTemp(); // 声明触发获取温度函数
/** 任务句柄，用于读取温度任务 */
TaskHandle_t tempTaskHandle = NULL;
/** 用于读取温度的Ticker */
Ticker tempTicker;
/** 舒适度状态 */
ComfortState cf;
/** 任务是否应该运行的标志 */
bool tasksEnabled = false;
/** DHT11数据引脚的引脚号 */
int dhtPin = 1;
/**
* initTemp
* 设置DHT库
* 设置任务和定时器以重复测量
* @return bool
* true 如果任务和定时器已启动
* false 如果任务或定时器无法启动
*/
bool initTemp() {
byte resultValue = 0;
// 初始化温度传感器
dht.setup(dhtPin, DHTesp::DHT11);
Serial.println("DHT initiated");
// 启动任务以获取温度
xTaskCreatePinnedToCore(
tempTask, /* 实现任务的函数 */
"tempTask ", /* 任务名称 */
4000, /* 堆栈大小（字） */
NULL, /* 任务输入参数 */
5, /* 任务优先级 */
&tempTaskHandle, /* 任务句柄 */
1); /* 任务应运行的核心 */
if (tempTaskHandle == NULL) {
Serial.println("Failed to start task for temperature update");
return false;
} else {
// 每20秒更新环境数据
tempTicker.attach(20, triggerGetTemp);
}
return true;
}
/**
* triggerGetTemp
* 设置标志dhtUpdated为true以便在loop()中处理
* 由Ticker getTempTimer调用
*/
void triggerGetTemp() {
if (tempTaskHandle != NULL) {
xTaskResumeFromISR(tempTaskHandle);
}
}
/**
* 任务从DHT11传感器读取温度
* @param pvParameters
* 指向任务参数的指针
*/
void tempTask(void *pvParameters) {
Serial.println("tempTask loop started");
while (1) // tempTask循环
{
if (tasksEnabled) {
// 获取温度值
getTemperature();
}
// 再次进入睡眠
vTaskSuspend(NULL);
}
}
/**
* getTemperature
* 从DHT11传感器读取温度
* @return bool
* true 如果温度获取成功
* false 如果获取失败
*/
bool getTemperature() {
// 读取湿度的温度大约需要250毫秒！
// 传感器读数也可能长达2秒“旧”（它是一个非常慢的传感器）
TempAndHumidity newValues = dht.getTempAndHumidity();
// 检查是否有任何读取失败并提前退出（以便再次尝试）。
if (dht.getStatus() != 0) {
Serial.println("DHT11 error status: " + String(dht.getStatusString()));
return false;
}
float heatIndex = dht.computeHeatIndex(newValues.temperature, newValues.humidity);
float dewPoint = dht.computeDewPoint(newValues.temperature, newValues.humidity);
float cr = dht.getComfortRatio(cf, newValues.temperature, newValues.humidity);
String comfortStatus;
switch(cf) {
case Comfort_OK:
comfortStatus = "舒适";
break;
case Comfort_TooHot:
comfortStatus = "太热";
break;
case Comfort_TooCold:
comfortStatus = "太冷";
break;
case Comfort_TooDry:
comfortStatus = "太干燥";
break;
case Comfort_TooHumid:
comfortStatus = "太潮湿";
break;
case Comfort_HotAndHumid:
comfortStatus = "又热又潮湿";
break;
case Comfort_HotAndDry:
comfortStatus = "又热又干燥";
break;
case Comfort_ColdAndHumid:
comfortStatus = "又冷又潮湿";
break;
case Comfort_ColdAndDry:
comfortStatus = "又冷又干燥";
break;
default:
comfortStatus = "未知状态";
break;
};
Serial.println(" 温度:" + String(newValues.temperature) + " 湿度:" + String(newValues.humidity) + " 热指数:" + String(heatIndex) + " 露点:" + String(dewPoint) + " " + comfortStatus);
return true;
}
void setup(){
Serial.begin(115200);
Serial.println();
Serial.println("DHT ESP32 任务示例");
initTemp();
// 向任务发出setup()结束的信号
tasksEnabled = true;
}
void loop() {
if (!tasksEnabled) {
// 等待2秒以让系统稳定下来
delay(2000);
// 启用将从DHT传感器读取值的任务
tasksEnabled = true;
if (tempTaskHandle != NULL) {
vTaskResume(tempTaskHandle);
}
}
yield();
}
【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
实验串口返回情况【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）实验二百三十二：ESP32-S3 WROOM N16R8 CAM开发板WiFi+蓝牙模块
OV2640/5640摄像头模组
{花雕动手做}项目之三十：ESP32-S3 CAM使用DHT11模块测量温湿度（简化版）
实验开源代码
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验二百三十二：ESP32-S3 WROOM N16R8 CAM开发板WiFi+蓝牙模块
OV2640/5640摄像头模组
{花雕动手做}项目之三十：ESP32-S3 CAM使用DHT11模块测量温湿度（简化版）
*/
#include "DHTesp.h" // 引入DHTesp库，用于处理DHT传感器
DHTesp dht; // 创建一个DHTesp对象，用于与DHT传感器通信
void setup() {
Serial.begin(115200); // 初始化串口通信，波特率设置为115200
dht.setup(1, DHTesp::DHT11); // 设置DHT传感器，数据引脚为GPIO 1，传感器类型为DHT11
}
void loop() {
delay(2000); // 等待2秒，给传感器足够的时间进行数据采集
TempAndHumidity newValues = dht.getTempAndHumidity(); // 从传感器读取温度和湿度值
if (dht.getStatus() != 0) { // 检查传感器状态，如果读取失败
Serial.println("DHT11 error status: " + String(dht.getStatusString())); // 打印错误状态信息
} else { // 如果读取成功
Serial.println("Temperature: " + String(newValues.temperature) + " *C"); // 打印温度值
Serial.println("Humidity: " + String(newValues.humidity) + " %"); // 打印湿度值
}
}
【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
代码解释1、引入库：
#include "DHTesp.h"
这行代码引入了 DHTesp 库，该库提供了与DHT传感器通信的功能。
2、创建对象：
DHTesp dht;
创建一个 DHTesp 对象 dht，用于与DHT传感器进行通信。
3、初始化设置：
void setup() {
Serial.begin(115200);
dht.setup(1, DHTesp::DHT11);
}
Serial.begin(115200);：初始化串口通信，设置波特率为115200。
dht.setup(1, DHTesp::DHT11);：设置DHT传感器，数据引脚为GPIO 1，传感器类型为DHT11。
4、主循环：
void loop() {
delay(2000);
TempAndHumidity newValues = dht.getTempAndHumidity();
if (dht.getStatus() != 0) {
Serial.println("DHT11 error status: " + String(dht.getStatusString()));
} else {
Serial.println("Temperature: " + String(newValues.temperature) + " *C");
Serial.println("Humidity: " + String(newValues.humidity) + " %");
}
}
delay(2000);：等待2秒，给传感器足够的时间进行数据采集。
TempAndHumidity newValues = dht.getTempAndHumidity();：从传感器读取温度和湿度值。
if (dht.getStatus() != 0) { ... }：检查传感器状态，如果读取失败，打印错误状态信息。
else { ... }：如果读取成功，打印温度和湿度值。
【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
实验串口返回情况【花雕学编程】Arduino动手做（232）---ESP32S3-CAM DHT11模块
实验场景图
页:
[1]