设为首页收藏本站
首页 > 论坛 > Arduino

[项目]【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表

驴友花雕 | 中级技神 | 创造力： | 帖子： | 发消息 | 串个门 | 加好友 | 打招呼
2025-6-24 20:34:05 [显示全部楼层]
87浏览
2回复
0收藏
查看: 87|回复: 2

[项目] 【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表

[复制链接]
频谱分析仪 VU 表在 ESP32 上运行 40kHz FFT 并输出到 16 x 16 FastLED 矩阵。该代码与最初由 G6EJD 编写的此示例进行了大量修改。
演示

如果您打算使用此代码，建议您观看下面的 YouTube 视频，了解其工作原理。请注意，由于视频的制作，代码已更改为使用 FastLED Neomatrix，这要归功于 VonHirsch。请参阅下面的“安装和代码使用”。

设置电路
矩阵将从线路输入或麦克风运行，因此请选择适合您的设置。为按钮选择图钉时，请小心。ESP32 上的一些引脚没有上拉电阻，如果您选择其中一个，按钮将不起作用！当我测试时，我发现 D2 不起作用，但 D4 有效，所以我选择了那个。

线路输入
输入的立体声信号首先使用两个 10K 电阻器转换为单声道，然后通过一个 100nF 电容器来阻断直流。然后，信号由两个 100k 电阻器偏置到 3.3V / 2 = 1.65V，以便 ADC 读取。这些值都不是关键的。电阻器应为 10k 或更高，并且每对应匹配。我尝试了从100nF 到10uF 的电容器，但没有注意到结果有任何差异。引脚 D5 是 LED 数据引脚，连接到矩阵中的第一个 LED。引脚 D2 连接到一个瞬时按钮，用于更改显示模式。

麦克风
这比 line in 方法简单得多，但您将受限于麦克风的灵敏度可以检测到的频率。您需要一个带有板载放大功能的麦克风，通常类似于 MAX4466 的东西，可以从 eBay 或 alixepress 便宜地购买。使用 I2S 麦克风会获得更好的结果，但这超出了本项目的范围。调高您拥有的任何麦克风的增益。麦克风应连接到 GND、3V3，输出引脚应连接到 D35。引脚 D5 是 LED 数据引脚，连接到矩阵中的第一个 LED。引脚 D2 连接到一个瞬时按钮，用于更改显示模式。

安装和代码使用
1. 下载此存储库并打开 ESP32_FFT_VU.ino。
2. 您将需要 Arduino 库管理器中的 FastLED、Neomatrix 和 EasyButton 库。您还需要 arduinoFFT 库。在撰写本文时，库管理器版本 arduinoFFT 存在一个阻止工作的错误，因此请从 GitHub 存储库下载它并从 zip 文件安装它。DCRemoval()
3. 观看视频以了解如何使用它。
4. 要将其自定义为您自己的矩阵布局，请阅读 Adafruit 上的 Neomatrix 布局。

控制
矩阵通过单个按钮进行控制。这些功能包括：
• 单击：更改模式
• 长按：更改亮度
• 2 秒内按下 3 个按钮：设置为自动更改模式
• 2 秒内按下 5 个按钮：关闭显示屏

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图1

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图2

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图3

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图5

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图4

回复

使用道具 举报

精彩评论(2)

驴友花雕  中级技神
 楼主|

发表于 2025-6-24 20:37:08

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表

项目代码

  1. // (Heavily) adapted from https://github.com/G6EJD/ESP32-8266-Audio-Spectrum-Display/blob/master/ESP32_Spectrum_Display_02.ino

  2. // Adjusted to allow brightness changes on press+hold, Auto-cycle for 3 button presses within 2 seconds

  3. // Edited to add Neomatrix support for easier compatibility with different layouts.

  4. 

  5. #include <FastLED_NeoMatrix.h>

  6. #include <arduinoFFT.h>

  7. #include <EasyButton.h>

  8. 

  9. #define SAMPLES         1024          // Must be a power of 2

  10. #define SAMPLING_FREQ   40000         // Hz, must be 40000 or less due to ADC conversion time. Determines maximum frequency that can be analysed by the FFT Fmax=sampleF/2.

  11. #define AMPLITUDE       1000          // Depending on your audio source level, you may need to alter this value. Can be used as a 'sensitivity' control.

  12. #define AUDIO_IN_PIN    35            // Signal in on this pin

  13. #define LED_PIN         5             // LED strip data

  14. #define BTN_PIN         4             // Connect a push button to this pin to change patterns

  15. #define LONG_PRESS_MS   200           // Number of ms to count as a long press

  16. #define COLOR_ORDER     GRB           // If colours look wrong, play with this

  17. #define CHIPSET         WS2812B       // LED strip type

  18. #define MAX_MILLIAMPS   2000          // Careful with the amount of power here if running off USB port

  19. const int BRIGHTNESS_SETTINGS[3] = {5, 70, 200};  // 3 Integer array for 3 brightness settings (based on pressing+holding BTN_PIN)

  20. #define LED_VOLTS       5             // Usually 5 or 12

  21. #define NUM_BANDS       16            // To change this, you will need to change the bunch of if statements describing the mapping from bins to bands

  22. #define NOISE           500           // Used as a crude noise filter, values below this are ignored

  23. const uint8_t kMatrixWidth = 16;                          // Matrix width

  24. const uint8_t kMatrixHeight = 16;                         // Matrix height

  25. #define NUM_LEDS       (kMatrixWidth * kMatrixHeight)     // Total number of LEDs

  26. #define BAR_WIDTH      (kMatrixWidth  / (NUM_BANDS - 1))  // If width >= 8 light 1 LED width per bar, >= 16 light 2 LEDs width bar etc

  27. #define TOP            (kMatrixHeight - 0)                // Don't allow the bars to go offscreen

  28. #define SERPENTINE     true                               // Set to false if you're LEDS are connected end to end, true if serpentine

  29. 

  30. // Sampling and FFT stuff

  31. unsigned int sampling_period_us;

  32. byte peak[] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};              // The length of these arrays must be >= NUM_BANDS

  33. int oldBarHeights[] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};

  34. int bandValues[] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};

  35. double vReal[SAMPLES];

  36. double vImag[SAMPLES];

  37. unsigned long newTime;

  38. arduinoFFT FFT = arduinoFFT(vReal, vImag, SAMPLES, SAMPLING_FREQ);

  39. 

  40. // Button stuff

  41. int buttonPushCounter = 0;

  42. bool autoChangePatterns = false;

  43. EasyButton modeBtn(BTN_PIN);

  44. 

  45. // FastLED stuff

  46. CRGB leds[NUM_LEDS];

  47. DEFINE_GRADIENT_PALETTE( purple_gp ) {

  48.   0,   0, 212, 255,   //blue

  49. 255, 179,   0, 255 }; //purple

  50. DEFINE_GRADIENT_PALETTE( outrun_gp ) {

  51.   0, 141,   0, 100,   //purple

  52. 127, 255, 192,   0,   //yellow

  53. 255,   0,   5, 255 };  //blue

  54. DEFINE_GRADIENT_PALETTE( greenblue_gp ) {

  55.   0,   0, 255,  60,   //green

  56.  64,   0, 236, 255,   //cyan

  57. 128,   0,   5, 255,   //blue

  58. 192,   0, 236, 255,   //cyan

  59. 255,   0, 255,  60 }; //green

  60. DEFINE_GRADIENT_PALETTE( redyellow_gp ) {

  61.   0,   200, 200,  200,   //white

  62.  64,   255, 218,    0,   //yellow

  63. 128,   231,   0,    0,   //red

  64. 192,   255, 218,    0,   //yellow

  65. 255,   200, 200,  200 }; //white

  66. CRGBPalette16 purplePal = purple_gp;

  67. CRGBPalette16 outrunPal = outrun_gp;

  68. CRGBPalette16 greenbluePal = greenblue_gp;

  69. CRGBPalette16 heatPal = redyellow_gp;

  70. uint8_t colorTimer = 0;

  71. 

  72. // FastLED_NeoMaxtrix - see https://github.com/marcmerlin/FastLED_NeoMatrix for Tiled Matrixes, Zig-Zag and so forth

  73. FastLED_NeoMatrix *matrix = new FastLED_NeoMatrix(leds, kMatrixWidth, kMatrixHeight,

  74.   NEO_MATRIX_TOP        + NEO_MATRIX_LEFT +

  75.   NEO_MATRIX_ROWS       + NEO_MATRIX_ZIGZAG +

  76.   NEO_TILE_TOP + NEO_TILE_LEFT + NEO_TILE_ROWS);

  77. 

  78. void setup() {

  79.   Serial.begin(115200);

  80.   FastLED.addLeds<CHIPSET, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS).setCorrection(TypicalSMD5050);

  81.   FastLED.setMaxPowerInVoltsAndMilliamps(LED_VOLTS, MAX_MILLIAMPS);

  82.   FastLED.setBrightness(BRIGHTNESS_SETTINGS[1]);

  83.   FastLED.clear();

  84. 

  85.   modeBtn.begin();

  86.   modeBtn.onPressed(changeMode);

  87.   modeBtn.onPressedFor(LONG_PRESS_MS, brightnessButton);

  88.   modeBtn.onSequence(3, 2000, startAutoMode);

  89.   modeBtn.onSequence(5, 2000, brightnessOff);

  90.   sampling_period_us = round(1000000 * (1.0 / SAMPLING_FREQ));

  91. }

  92. 

  93. void changeMode() {

  94.   Serial.println("Button pressed");

  95.   if (FastLED.getBrightness() == 0) FastLED.setBrightness(BRIGHTNESS_SETTINGS[0]);  //Re-enable if lights are "off"

  96.   autoChangePatterns = false;

  97.   buttonPushCounter = (buttonPushCounter + 1) % 6;

  98. }

  99. 

  100. void startAutoMode() {

  101.   autoChangePatterns = true;

  102. }

  103. 

  104. void brightnessButton() {

  105.   if (FastLED.getBrightness() == BRIGHTNESS_SETTINGS[2])  FastLED.setBrightness(BRIGHTNESS_SETTINGS[0]);

  106.   else if (FastLED.getBrightness() == BRIGHTNESS_SETTINGS[0]) FastLED.setBrightness(BRIGHTNESS_SETTINGS[1]);

  107.   else if (FastLED.getBrightness() == BRIGHTNESS_SETTINGS[1]) FastLED.setBrightness(BRIGHTNESS_SETTINGS[2]);

  108.   else if (FastLED.getBrightness() == 0) FastLED.setBrightness(BRIGHTNESS_SETTINGS[0]); //Re-enable if lights are "off"

  109. }

  110. 

  111. void brightnessOff(){

  112.   FastLED.setBrightness(0);  //Lights out

  113. }

  114. 

  115. void loop() {

  116. 

  117.   // Don't clear screen if waterfall pattern, be sure to change this is you change the patterns / order

  118.   if (buttonPushCounter != 5) FastLED.clear();

  119. 

  120.   modeBtn.read();

  121. 

  122.   // Reset bandValues[]

  123.   for (int i = 0; i<NUM_BANDS; i++){

  124.     bandValues[i] = 0;

  125.   }

  126. 

  127.   // Sample the audio pin

  128.   for (int i = 0; i < SAMPLES; i++) {

  129.     newTime = micros();

  130.     vReal[i] = analogRead(AUDIO_IN_PIN); // A conversion takes about 9.7uS on an ESP32

  131.     vImag[i] = 0;

  132.     while ((micros() - newTime) < sampling_period_us) { /* chill */ }

  133.   }

  134. 

  135.   // Compute FFT

  136.   FFT.DCRemoval();

  137.   FFT.Windowing(FFT_WIN_TYP_HAMMING, FFT_FORWARD);

  138.   FFT.Compute(FFT_FORWARD);

  139.   FFT.ComplexToMagnitude();

  140. 

  141.   // Analyse FFT results

  142.   for (int i = 2; i < (SAMPLES/2); i++){       // Don't use sample 0 and only first SAMPLES/2 are usable. Each array element represents a frequency bin and its value the amplitude.

  143.     if (vReal[i] > NOISE) {                    // Add a crude noise filter

  144. 

  145.     /*8 bands, 12kHz top band

  146.       if (i<=3 )           bandValues[0]  += (int)vReal[i];

  147.       if (i>3   && i<=6  ) bandValues[1]  += (int)vReal[i];

  148.       if (i>6   && i<=13 ) bandValues[2]  += (int)vReal[i];

  149.       if (i>13  && i<=27 ) bandValues[3]  += (int)vReal[i];

  150.       if (i>27  && i<=55 ) bandValues[4]  += (int)vReal[i];

  151.       if (i>55  && i<=112) bandValues[5]  += (int)vReal[i];

  152.       if (i>112 && i<=229) bandValues[6]  += (int)vReal[i];

  153.       if (i>229          ) bandValues[7]  += (int)vReal[i];*/

  154. 

  155.     //16 bands, 12kHz top band

  156.       if (i<=2 )           bandValues[0]  += (int)vReal[i];

  157.       if (i>2   && i<=3  ) bandValues[1]  += (int)vReal[i];

  158.       if (i>3   && i<=5  ) bandValues[2]  += (int)vReal[i];

  159.       if (i>5   && i<=7  ) bandValues[3]  += (int)vReal[i];

  160.       if (i>7   && i<=9  ) bandValues[4]  += (int)vReal[i];

  161.       if (i>9   && i<=13 ) bandValues[5]  += (int)vReal[i];

  162.       if (i>13  && i<=18 ) bandValues[6]  += (int)vReal[i];

  163.       if (i>18  && i<=25 ) bandValues[7]  += (int)vReal[i];

  164.       if (i>25  && i<=36 ) bandValues[8]  += (int)vReal[i];

  165.       if (i>36  && i<=50 ) bandValues[9]  += (int)vReal[i];

  166.       if (i>50  && i<=69 ) bandValues[10] += (int)vReal[i];

  167.       if (i>69  && i<=97 ) bandValues[11] += (int)vReal[i];

  168.       if (i>97  && i<=135) bandValues[12] += (int)vReal[i];

  169.       if (i>135 && i<=189) bandValues[13] += (int)vReal[i];

  170.       if (i>189 && i<=264) bandValues[14] += (int)vReal[i];

  171.       if (i>264          ) bandValues[15] += (int)vReal[i];

  172.     }

  173.   }

  174. 

  175.   // Process the FFT data into bar heights

  176.   for (byte band = 0; band < NUM_BANDS; band++) {

  177. 

  178.     // Scale the bars for the display

  179.     int barHeight = bandValues[band] / AMPLITUDE;

  180.     if (barHeight > TOP) barHeight = TOP;

  181. 

  182.     // Small amount of averaging between frames

  183.     barHeight = ((oldBarHeights[band] * 1) + barHeight) / 2;

  184. 

  185.     // Move peak up

  186.     if (barHeight > peak[band]) {

  187.       peak[band] = min(TOP, barHeight);

  188.     }

  189. 

  190.     // Draw bars

  191.     switch (buttonPushCounter) {

  192.       case 0:

  193.         rainbowBars(band, barHeight);

  194.         break;

  195.       case 1:

  196.         // No bars on this one

  197.         break;

  198.       case 2:

  199.         purpleBars(band, barHeight);

  200.         break;

  201.       case 3:

  202.         centerBars(band, barHeight);

  203.         break;

  204.       case 4:

  205.         changingBars(band, barHeight);

  206.         break;

  207.       case 5:

  208.         waterfall(band);

  209.         break;

  210.     }

  211. 

  212.     // Draw peaks

  213.     switch (buttonPushCounter) {

  214.       case 0:

  215.         whitePeak(band);

  216.         break;

  217.       case 1:

  218.         outrunPeak(band);

  219.         break;

  220.       case 2:

  221.         whitePeak(band);

  222.         break;

  223.       case 3:

  224.         // No peaks

  225.         break;

  226.       case 4:

  227.         // No peaks

  228.         break;

  229.       case 5:

  230.         // No peaks

  231.         break;

  232.     }

  233. 

  234.     // Save oldBarHeights for averaging later

  235.     oldBarHeights[band] = barHeight;

  236.   }

  237. 

  238.   // Decay peak

  239.   EVERY_N_MILLISECONDS(60) {

  240.     for (byte band = 0; band < NUM_BANDS; band++)

  241.       if (peak[band] > 0) peak[band] -= 1;

  242.     colorTimer++;

  243.   }

  244. 

  245.   // Used in some of the patterns

  246.   EVERY_N_MILLISECONDS(10) {

  247.     colorTimer++;

  248.   }

  249. 

  250.   EVERY_N_SECONDS(10) {

  251.     if (autoChangePatterns) buttonPushCounter = (buttonPushCounter + 1) % 6;

  252.   }

  253. 

  254.   FastLED.show();

  255. }

  256. 

  257. // PATTERNS BELOW //

  258. 

  259. void rainbowBars(int band, int barHeight) {

  260.   int xStart = BAR_WIDTH * band;

  261.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  262.     for (int y = TOP; y >= TOP - barHeight; y--) {

  263.       matrix->drawPixel(x, y, CHSV((x / BAR_WIDTH) * (255 / NUM_BANDS), 255, 255));

  264.     }

  265.   }

  266. }

  267. 

  268. void purpleBars(int band, int barHeight) {

  269.   int xStart = BAR_WIDTH * band;

  270.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  271.     for (int y = TOP; y >= TOP - barHeight; y--) {

  272.       matrix->drawPixel(x, y, ColorFromPalette(purplePal, y * (255 / (barHeight + 1))));

  273.     }

  274.   }

  275. }

  276. 

  277. void changingBars(int band, int barHeight) {

  278.   int xStart = BAR_WIDTH * band;

  279.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  280.     for (int y = TOP; y >= TOP - barHeight; y--) {

  281.       matrix->drawPixel(x, y, CHSV(y * (255 / kMatrixHeight) + colorTimer, 255, 255));

  282.     }

  283.   }

  284. }

  285. 

  286. void centerBars(int band, int barHeight) {

  287.   int xStart = BAR_WIDTH * band;

  288.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  289.     if (barHeight % 2 == 0) barHeight--;

  290.     int yStart = ((kMatrixHeight - barHeight) / 2 );

  291.     for (int y = yStart; y <= (yStart + barHeight); y++) {

  292.       int colorIndex = constrain((y - yStart) * (255 / barHeight), 0, 255);

  293.       matrix->drawPixel(x, y, ColorFromPalette(heatPal, colorIndex));

  294.     }

  295.   }

  296. }

  297. 

  298. void whitePeak(int band) {

  299.   int xStart = BAR_WIDTH * band;

  300.   int peakHeight = TOP - peak[band] - 1;

  301.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  302.     matrix->drawPixel(x, peakHeight, CHSV(0,0,255));

  303.   }

  304. }

  305. 

  306. void outrunPeak(int band) {

  307.   int xStart = BAR_WIDTH * band;

  308.   int peakHeight = TOP - peak[band] - 1;

  309.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  310.     matrix->drawPixel(x, peakHeight, ColorFromPalette(outrunPal, peakHeight * (255 / kMatrixHeight)));

  311.   }

  312. }

  313. 

  314. void waterfall(int band) {

  315.   int xStart = BAR_WIDTH * band;

  316.   double highestBandValue = 60000;        // Set this to calibrate your waterfall

  317. 

  318.   // Draw bottom line

  319.   for (int x = xStart; x < xStart + BAR_WIDTH; x++) {

  320.     matrix->drawPixel(x, 0, CHSV(constrain(map(bandValues[band],0,highestBandValue,160,0),0,160), 255, 255));

  321.   }

  322. 

  323.   // Move screen up starting at 2nd row from top

  324.   if (band == NUM_BANDS - 1){

  325.     for (int y = kMatrixHeight - 2; y >= 0; y--) {

  326.       for (int x = 0; x < kMatrixWidth; x++) {

  327.         int pixelIndexY = matrix->XY(x, y + 1);

  328.         int pixelIndex = matrix->XY(x, y);

  329.         leds[pixelIndexY] = leds[pixelIndex];

  330.       }

  331.     }

  332.   }

  333. }
复制代码


回复

使用道具 举报

驴友花雕  中级技神
 楼主|

发表于 2025-6-24 20:39:50

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表
项目链接：https://www.youtube.com/watch?v=Mgh2WblO5_c
项目作者：斯科特·马利，ALTech DIY

项目视频 ：https://www.youtube.com/watch?v=26SWWaKUnCg&t=551s
项目代码：https://github.com/s-marley/ESP32_FFT_VU
arduinoFFT库：https://github.com/kosme/arduinoFFT

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图1

【Arduino 动手做】FastLED矩阵的ESP32频谱分析仪VU表图2

回复

使用道具 举报

高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

为本项目制作心愿单
购买心愿单
心愿单 编辑
[[wsData.name]]

硬件清单

  • [[d.name]]
btnicon
我也要做!
点击进入购买页面
撰写新帖
关于楼主
勋章墙
萌萌哒新人 活跃会员 宣传大使 牛X认证 创作达人 ARD DAY 摸鱼团员 志“童”道合 编辑选择奖

楼主的其它帖子

background 创造力兑换 background 心愿单 background 创客导航
上海智位机器人股份有限公司 沪ICP备09038501号-4 备案 沪公网安备31011502402448

© 2013-2025 Comsenz Inc. Powered by Discuz! X3.4 Licensed

mail